blob: c6492c86ddc4ab2caa9dfbb6ed70ab2ce2905c89 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
|
# Maintainer: Daniel Bermond <dbermond@archlinux.org>
pkgname=intel-media-driver-git
pkgver=2020.4.0.r113.g2eeb7e50
pkgrel=1
pkgdesc='Intel Media Driver for VAAPI — Broadwell+ iGPUs (git version)'
arch=('x86_64')
url='https://github.com/intel/media-driver/'
license=('MIT' 'BSD')
depends=(
# official repositories:
'gcc-libs' 'libpciaccess'
# AUR:
'intel-gmmlib-git' 'libva-git'
)
makedepends=('git' 'cmake')
provides=('intel-media-driver')
conflicts=('intel-media-driver')
source=('git+https://github.com/intel/media-driver.git')
sha256sums=('SKIP')
pkgver() {
git -C media-driver describe --long --tags | sed 's/^intel-media-//;s/^[0-9]\{2\}/20&/;s/\([^-]*-g\)/r\1/;s/-/./g;s/^v//'
}
build() {
cmake -B build -S media-driver \
-DCMAKE_INSTALL_PREFIX:PATH='/usr' \
-DINSTALL_DRIVER_SYSCONF:BOOL='OFF' \
-Wno-dev
make -C build
}
package() {
make -C build DESTDIR="$pkgdir" install
install -D -m644 media-driver/LICENSE.md "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
}
|