blob: ca5eb63bde2f9aa7e73f6523ef0fbe31dd64f102 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
|
# Maintainer: Daniel Bermond < gmail-com: danielbermond >
pkgname=intel-seapi-git
_srcname=IntelSEAPI
pkgver=17.01.28.r25.gf41831f
pkgrel=5
pkgdesc='Intel Single Event API (Intel SEAPI) (git version)'
arch=('i686' 'x86_64')
url='https://github.com/intel/IntelSEAPI/'
license=('BSD' 'GPL')
depends=('gcc-libs')
makedepends=('git' 'python' 'cmake' 'java-environment' 'classpath')
optdepends=('python: for using runtool modules')
provides=('intel-seapi')
conflicts=('intel-seapi')
source=('git+https://github.com/intel/IntelSEAPI.git'
'intel-seapi-git-change-install-prefix.patch')
sha256sums=('SKIP'
'2b8b415490503e19bbd432b0dc958ca9b4ee154dcfd1e97642e3025a7d6c9d7e')
[ "$CARCH" = 'i686' ] && _architecture='32'
[ "$CARCH" = 'x86_64' ] && _architecture='64'
prepare() {
cd "$_srcname"
# change install prefix to '/usr' instead of '/usr/local'
patch -Np1 -i "${srcdir}/intel-seapi-git-change-install-prefix.patch"
}
pkgver() {
cd "$_srcname"
# git, tags available
git describe --long --tags | sed 's/\([^-]*-g\)/r\1/;s/-/./g;s/^v//;s/,//'
}
build() {
cd "$_srcname"
python ./buildall.py --force_bits "$_architecture"
}
package() {
cd "${_srcname}/build_linux/${_architecture}"
make DESTDIR="$pkgdir" install
# library
mv "${pkgdir}/usr/bin/libIntelSEAPI${_architecture}.so" "${pkgdir}/usr/lib"
# python
local _pythonver
_pythonver="$(python -c 'import sys; print("%s.%s" % sys.version_info[:2])')"
mkdir -p "${pkgdir}/usr/lib/python${_pythonver}/${pkgname%%-git}"
mv "$pkgdir"/usr/runtool/* "${pkgdir}/usr/lib/python${_pythonver}/${pkgname%%-git}"
# cleanup
rm -r "${pkgdir}/usr/runtool"
rm "${pkgdir}/usr/README.txt"
# license
cd "${srcdir}/${_srcname}/ittnotify/src/ittnotify"
install -D -m644 LICENSE.BSD -t "${pkgdir}/usr/share/licenses/${pkgname}"
}
|