blob: 01b278d86f2c987ef6f0f6052160f3036a2b0ac9 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
|
# Maintainer: Thomas Quillan <tjquillan@gmail.com>
pkgname=intellij-idea-community-edition-jre
_appname=jetbrains-idea-ce
pkgver=2020.2.1
_buildver=202.6948.69
pkgrel=1
pkgdesc="Intellij Idea Community Edition with bundled JRE"
arch=('any')
url="http://www.jetbrains.com/idea/"
license=("Apache2")
depends=('giflib' 'libxtst' 'python' 'sh' 'ttf-font' 'libdbusmenu-glib')
provides=("$_appname")
conflicts=("$_appname")
source=("https://download.jetbrains.com/idea/ideaIC-$pkgver.tar.gz"
"$_appname.desktop")
sha256sums=('a107f09ae789acc1324fdf8d22322ea4e4654656c742e4dee8a184e265f1b014'
'91aa66e16e428d595c9f76a02f5a6d54d6fb0b1d1ccac4159cfb7070cff26a4b')
package() {
cd idea-IC-"$_buildver"
# workaround FS#40934
sed -i 's/lcd/on/' bin/*.vmoptions
install -dm 755 "$pkgdir"/usr/bin
install -dm 755 "$pkgdir"/usr/share/{licenses,pixmaps,"$_appname",icons/hicolor/scalable/apps}
cp -dr --no-preserve='ownership' bin jbr lib plugins redist build.txt product-info.json "$pkgdir"/usr/share/"$_appname/"
cp -dr --no-preserve='ownership' license "$pkgdir"/usr/share/licenses/"$_appname"
ln -s /usr/share/"$_appname"/bin/idea.png "$pkgdir"/usr/share/pixmaps/"$_appname".png
ln -s /usr/share/"$_appname"/bin/idea.svg "${pkgdir}"/usr/share/icons/hicolor/scalable/apps/"$_appname".svg
install -Dm 644 ../"$_appname".desktop -t "$pkgdir"/usr/share/applications/
ln -s /usr/share/"$_appname"/bin/idea.sh "$pkgdir"/usr/bin/idea-ce
}
|