blob: 34f4a6250f7b1af2c2f1e65fac0be2877431f6b8 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
|
# Maintainer: D. Can Celasun <can[at]dcc[dot]im>
# Co-Maintainer: Urs Wolfer <uwolfer @ fwo.ch>
pkgbase=intellij-idea-ultimate-edition
pkgname=(intellij-idea-ultimate-edition intellij-idea-ultimate-edition-jre)
pkgver=2024.1
pkgrel=1
_buildver=241.14494.240
jbr_ver=21.0.2
jbr_build=aarch64-b346
jbr_minor=3
arch=('x86_64' 'aarch64')
pkgdesc="An intelligent IDE for Java, Groovy and other programming languages with advanced refactoring features intensely focused on developer productivity."
url="https://www.jetbrains.com/idea/"
license=('custom:commercial')
options=(!strip)
source=("https://download-cf.jetbrains.com/idea/ideaIU-$pkgver.tar.gz"
"jetbrains-idea.desktop")
source_aarch64=("https://cache-redirector.jetbrains.com/intellij-jbr/jbr-$jbr_ver-linux-$jbr_build.$jbr_minor.tar.gz"
"https://github.com/JetBrains/intellij-community/raw/master/bin/linux/aarch64/fsnotifier")
sha256sums=('b9083da939eacbcdf24b84cb9c45a1291bb33715f05fc7e10f2cff065d7c3fea'
'83af2ba8f9f14275a6684e79d6d4bd9b48cd852c047dacfc81324588fa2ff92b')
sha256sums_aarch64=('1bb237ede4123b425bb3270b2ac7a5a94375ebb4cf6f53dde8084d5637c87c4e'
'eb3c61973d34f051dcd3a9ae628a6ee37cd2b24a1394673bb28421a6f39dae29')
prepare() {
# Extract the JRE from the main pacakge
if [ -d "$srcdir"/jbr ]; then
rm -rf "$srcdir"/jbr
fi
# https://youtrack.jetbrains.com/articles/IDEA-A-48/JetBrains-IDEs-on-AArch64#linux
if [ "${CARCH}" == "aarch64" ]; then
cp -a "$srcdir"/jbr-${jbr_ver}-linux-${jbr_build}.${jbr_minor} "$srcdir"/jbr
cp -f fsnotifier "$srcdir"/idea-IU-$_buildver/bin/fsnotifier
chmod +x "$srcdir"/idea-IU-$_buildver/bin/fsnotifier
rm -rf "$srcdir"/idea-IU-$_buildver/jbr
else
mv "$srcdir"/idea-IU-$_buildver/jbr "$srcdir"/jbr
fi
}
package_intellij-idea-ultimate-edition() {
backup=("opt/${pkgname}/bin/idea64.vmoptions" "opt/${pkgname}/bin/idea.properties")
depends=('giflib' 'libxtst' 'libxrender')
optdepends=(
'intellij-idea-ultimate-edition-jre: JetBrains custom JRE (Recommended)' 'java-environment: Required if intellij-idea-ultimate-edition-jre is not installed'
'libdbusmenu-glib: For global menu support'
)
cd "$srcdir"
install -d "$pkgdir"/{opt/$pkgname,usr/bin}
mv idea-IU-${_buildver}/* "$pkgdir"/opt/$pkgbase
# https://youtrack.jetbrains.com/issue/IDEA-185828
chmod +x "$pkgdir"/opt/$pkgbase/plugins/maven/lib/maven3/bin/mvn
ln -s /opt/$pkgname/bin/idea.sh "$pkgdir"/usr/bin/$pkgname
install -D -m644 "$srcdir"/jetbrains-idea.desktop "$pkgdir"/usr/share/applications/jetbrains-idea.desktop
install -D -m644 "$pkgdir"/opt/$pkgbase/bin/idea.svg "$pkgdir"/usr/share/pixmaps/"$pkgname".svg
# workaround FS#40934
sed -i 's|lcd|on|' "$pkgdir"/opt/$pkgname/bin/*.vmoptions
}
package_intellij-idea-ultimate-edition-jre() {
url="https://github.com/JetBrains/JetBrainsRuntime"
install -d -m 755 "$pkgdir"/opt/$pkgbase
mv "$srcdir"/jbr "$pkgdir"/opt/$pkgbase
}
# vim:set ts=2 sw=2 et:
|