PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76

# Maintainer: Leonid Murin (Dasperal) <Dasperal1 at gmail dot com>
pkgbase=inter-doom-git
pkgname=('inter-doom-git' 'inter-heretic-git' 'inter-hexen-git')
pkgver=8.r777
pkgrel=1
arch=('i686' 'x86_64' 'armv7h' 'aarch64')
url="https://github.com/JNechaevsky/international-doom"
license=('GPL-2.0-only')
depends=('sdl2>=2.0.18' 'sdl2_mixer>=2.0.2' 'sdl2_net>=2.0.0' 'libsamplerate' 'fluidsynth')
makedepends=(cmake)
source=("git+https://github.com/JNechaevsky/international-doom.git"
        001_install_rule.patch)
b2sums=('SKIP'
        '653663f4e6ea5c26b85553bb9a50fce166973471ced0a7cd874bdb6dcad99a21b0d0c3084cb36ca34218c784c8f9611bcbba75ffbc53aeb59a7ecbbe8090f080')

pkgver() {
    cd "$srcdir/international-doom"
    printf "8.r%s" "$(git rev-list --count HEAD)"
}

prepare() {
  cd "international-doom"

  for patch in ../*.patch; do
    if [ ! -f "$patch" ]; then
      break;
    else
      patch -p1 -i "$patch"
    fi
  done
}

build() {
    # Upstream forces `-O2` for 'Release' build type
    cmake -S "international-doom" -B "build" \
    -D CMAKE_BUILD_TYPE="Release" \
    -D CMAKE_C_FLAGS_RELEASE="-O2 -DNDEBUG" \
    -D CMAKE_INSTALL_PREFIX="/usr"
    cmake --build "build"
}

package_inter-doom-git() {
    pkgdesc="Small, functional and simple Doom source port, created with help, efforts and bits of code from people around the world (git version)"
    conflicts=('inter-doom')
    optdepends=('doom1-wad: Doom shareware game data')

    DESTDIR="${pkgdir}" cmake --install build
    mv "${pkgdir}/usr/bin/inter-setup" "${pkgdir}/usr/bin/inter-doom-setup"
    rm "${pkgdir}/usr/bin/inter-heretic"
    rm "${pkgdir}/usr/bin/inter-hexen"
    install -Dm644 "international-doom/COPYING" "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
}

package_inter-heretic-git() {
    pkgdesc="Small, functional and simple Heretic source port, created with help, efforts and bits of code from people around the world (git version)"
    conflicts=('inter-heretic')
    optdepends=('heretic1-wad: Heretic shareware game data')

    DESTDIR="${pkgdir}" cmake --install build
    mv "${pkgdir}/usr/bin/inter-setup" "${pkgdir}/usr/bin/inter-heretic-setup"
    rm "${pkgdir}/usr/bin/inter-doom"
    rm "${pkgdir}/usr/bin/inter-hexen"
    install -Dm644 "international-doom/COPYING" "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
}

package_inter-hexen-git() {
    pkgdesc="Small, functional and simple Hexen source port, created with help, efforts and bits of code from people around the world (git version)"
    conflicts=('inter-hexen')
    optdepends=('hexen1-wad: Hexen demo game data')

    DESTDIR="${pkgdir}" cmake --install build
    mv "${pkgdir}/usr/bin/inter-setup" "${pkgdir}/usr/bin/inter-hexen-setup"
    rm "${pkgdir}/usr/bin/inter-doom"
    rm "${pkgdir}/usr/bin/inter-heretic"
    install -Dm644 "international-doom/COPYING" "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
}