blob: 0811d99d8aa84eb8d85a9706d464cc1446511d7b (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
|
# Maintainer: mario.valderrama <mv-aur@ransomware.download>
# Maintainer: matthias.lisin <ml-aur@ransomware.download>
pkgname=ionosctl
pkgver=6.7.0
pkgrel=1
pkgdesc='IONOS Cloud CLI'
arch=('x86_64' 'i686' 'aarch64' 'arm' 'armv6h' 'armv7h')
url='https://github.com/ionos-cloud/ionosctl'
license=('Apache')
depends=('glibc')
makedepends=('go' 'git')
source=("$url/archive/v$pkgver/$pkgname-$pkgver.tar.gz")
sha256sums=('dc34d3296be842f99704cf68a88a3ddef7d1b769cb4bf21470fe2b28e8b0235f')
build() {
_commit=$(bsdcat "$pkgname-$pkgver.tar.gz" | git get-tar-commit-id)
cd "$pkgname-$pkgver"
export CGO_ENABLED=1
export CGO_CFLAGS="$CFLAGS"
export CGO_CPPFLAGS="$CPPFLAGS"
export CGO_CXXFLAGS="$CXXFLAGS"
export CGO_LDFLAGS="$LDFLAGS"
export GOFLAGS='-buildmode=pie -modcacherw -trimpath'
go build -o "$pkgname" -ldflags "-linkmode=external \
-X=github.com/ionos-cloud/ionosctl/v6/commands.Version=$pkgver
-X=github.com/ionos-cloud/ionosctl/v6/commands.Label=release
-X=github.com/ionos-cloud/ionosctl/v6/commands.GitCommit=${_commit:?}" main.go
for i in bash zsh fish; do
./"$pkgname" completion "$i" >completion."$i"
done
}
package() {
cd "$pkgname-$pkgver"
install -Dm755 "$pkgname" -t "$pkgdir"/usr/bin
install -Dm644 completion.bash "$pkgdir"/usr/share/bash-completion/completions/"$pkgname"
install -Dm644 completion.zsh "$pkgdir"/usr/share/zsh/site-functions/_"$pkgname"
install -Dm644 completion.fish "$pkgdir"/usr/share/fish/vendor_completions.d/"$pkgname".fish
install -dm755 "$pkgdir"/usr/share/doc/"$pkgname"
cp -a docs -T "$pkgdir"/usr/share/doc/"$pkgname"
}
|