blob: be0e7cd9f3499e6cecbf21a239984710b9705e85 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
|
# Maintainer: Conrad Hoffmann <ch@bitfehler.net>
pkgname=ipcalc-redhat
pkgver=1.0.2
pkgrel=1
pkgdesc="Redhat's modernized ipcalc fork with IPv6 support"
arch=('x86_64')
url="https://gitlab.com/ipcalc/ipcalc"
license=('GPL')
conflicts=('ipcalc')
depends=('glibc')
makedepends=('meson' 'ruby-ronn')
source=("https://gitlab.com/ipcalc/ipcalc/-/archive/${pkgver}/ipcalc-${pkgver}.tar.gz")
sha256sums=('d48d1f459703edfaf7b7f2f801be776065c3d0ca3fea2a79b2896c01df8b3f42')
# Gitlab's tarballs now always contain a folder named after the commit :/
_relcommit="4c4261a47f355946ee74013d4f5d0494487cc2d6"
build() {
cd "$srcdir/ipcalc-$_relcommit"
meson setup build -Duse_maxminddb=disabled -Duse_geoip=disabled
ninja -C build
}
package() {
cd "$srcdir/ipcalc-$_relcommit"
install -m755 -Dt "${pkgdir}/usr/bin/" build/ipcalc
install -m644 -Dt "${pkgdir}/usr/share/licenses/ipcalc/" COPYING
install -m644 -Dt "${pkgdir}/usr/share/man/man1/" build/ipcalc.1
}
|