blob: 994ee5db3c0e50c0ed2c02d2cf4eca167bb27d1f (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
|
# Maintainer: Chocobo1 <chocobo1 AT archlinux DOT net>
pkgname=ipset-git
pkgver=7.1.r3.g8eaaf16
pkgrel=1
pkgdesc="Administration tool for IP sets"
arch=('i686' 'x86_64')
url="http://ipset.netfilter.org/"
license=('GPL2')
depends=('glibc' 'libmnl')
makedepends=('git')
provides=('ipset')
conflicts=('ipset')
backup=('etc/ipset.conf')
options=('staticlibs')
source=("git://git.netfilter.org/ipset"
"ipset.service::https://git.archlinux.org/svntogit/packages.git/plain/trunk/ipset.service?h=packages/ipset")
sha256sums=('SKIP'
'SKIP')
pkgver() {
cd "ipset"
git describe --long --tags | sed 's/^v//;s/\([^-]*-g\)/r\1/;s/-/./g'
}
build() {
cd "ipset"
./autogen.sh
./configure \
--prefix="/usr" \
--sbindir="/usr/bin" \
--with-kmod=no
make
}
package() {
cd "ipset"
make DESTDIR="$pkgdir" install
install -Dm644 "$srcdir/ipset.service" "$pkgdir/usr/lib/systemd/system/ipset.service"
install -Dm644 /dev/null "$pkgdir/etc/ipset.conf"
}
|