blob: 186a463e85c1706511b07e5e6c0eee7176d5da95 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
|
# Maintainer: Chocobo1 <chocobo1 AT archlinux DOT net>
pkgname=iputils-git
pkgver=20240117.r11.g3400f3a
pkgrel=1
pkgdesc="Network monitoring tools, including ping"
arch=('i686' 'x86_64')
url="https://github.com/iputils/iputils"
license=('GPL-2.0-or-later' 'BSD-3-Clause')
depends=('glibc' 'libcap' 'libidn2' 'openssl')
makedepends=('git' 'meson' 'libxslt')
provides=("iputils=$pkgver")
conflicts=('iputils' 'arping' 'netkit-base')
source=("git+https://github.com/iputils/iputils.git")
sha256sums=('SKIP')
pkgver() {
cd "iputils"
git describe --long --tags | sed 's/\([^-]*-g\)/r\1/;s/-/./g'
}
build() {
cd "iputils"
meson setup \
--buildtype=plain \
--prefix="/usr" \
--sbindir="bin" \
"_build"
meson compile -C "_build"
}
check() {
cd "iputils"
meson test -C "_build"
}
package() {
cd "iputils"
meson install -C "_build" --destdir "$pkgdir"
install -Dm644 "LICENSE" -t "$pkgdir/usr/share/licenses/iputils"
install -Dm644 "Documentation/LICENSE.BSD3" -t "$pkgdir/usr/share/licenses/iputils"
}
|