blob: 927eb4525aa519650f601cbafdb51e0f6ebd1952 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
|
# Maintainer: Chocobo1 <chocobo1 AT archlinux DOT net>
pkgname=iputils-git
pkgver=s20161105.r31.gef740f5
pkgrel=1
pkgdesc="Network monitoring tools, including ping"
arch=('i686' 'x86_64')
url="https://github.com/iputils/iputils"
license=('Custom')
depends=('glibc' 'libcap' 'libidn' 'openssl')
optdepends=('xinetd: for tftpd')
makedepends=('git' 'libxslt')
provides=('iputils')
conflicts=('iputils')
backup=(etc/xinetd.d/tftp)
install=iputils.install
source=("git+https://github.com/iputils/iputils.git"
"tftp.xinetd::https://git.archlinux.org/svntogit/packages.git/plain/trunk/tftp.xinetd?h=packages/iputils")
sha256sums=('SKIP'
'SKIP')
pkgver() {
cd "iputils"
git describe --long --tags | sed 's/\([^-]*-g\)/r\1/;s/-/./g'
}
build() {
cd "iputils"
make CCOPTOPT="$CFLAGS" USE_NETTLE=no
make -C doc man
}
package() {
cd "iputils"
install -dm755 "$pkgdir/usr/bin"
install -m755 arping clockdiff ping rarpd rdisc tftpd tracepath \
"$pkgdir/usr/bin/"
install -dm755 "$pkgdir/usr/share/man/man8"
install -m644 doc/{arping,clockdiff,ping,rarpd,rdisc,tftpd,tracepath}.8 \
"$pkgdir/usr/share/man/man8/"
install -Dm644 "LICENSE" "$pkgdir/usr/share/licenses/iputils/LICENSE"
install -Dm644 "LICENSE.BSD3" "$pkgdir/usr/share/licenses/iputils/LICENSE.BSD3"
install -Dm644 "$srcdir/tftp.xinetd" "$pkgdir/etc/xinetd.d/tftp"
}
|