blob: f05684f7434d21aa1c9e2f168fb52c9f79f8f9b6 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
|
# Contributor: Franco Tortoriello
# Contributor: Aaron Griffin <aaron@archlinux.org>
# Contributor: Aurelien Foret <orelien@chez.com>
pkgname=irda-utils
pkgver=0.9.18
pkgrel=3
pkgdesc='Utilities for infrared communication between devices'
url="http://irda.sourceforge.net"
arch=(i686 x86_64)
license=(GPL)
depends=(glib2 pciutils)
source=(http://downloads.sourceforge.net/irda/$pkgname-$pkgver.tar.gz
irda.service)
md5sums=('84dc12aa4c3f61fccb8d8919bf4079bb'
'cdcee6ba50ce437a9804250119134ee7')
prepare(){
cd "$srcdir/$pkgname-$pkgver"
# Fix header locations
sed -e 's|asm/io.h|sys/io.h|' -i \
findchip/{winbond,smc,nsc}.c pcmcia/ircard_cs.c
sed -i -e 's|inline ||g' irdadump/*.c
# Fix paths
sed -e 's|$(PREFIX)/usr/man|$(ROOT)/usr/share/man|' -i man/Makefile
sed -e 's|/usr/sbin/|$(ROOT)/usr/bin|' -i irnetd/Makefile
# /usr/sbin -> /usr/bin
sed -e 's|sbin|bin|' -i \
{irdaping,irdadump,findchip,irattach,smcinit}/Makefile
}
build() {
cd "$srcdir/$pkgname-$pkgver"
make
}
package() {
cd "$srcdir/$pkgname-$pkgver"
install -d "$pkgdir/usr/bin"
make ROOT="$pkgdir" install
install -Dm644 "$srcdir/irda.service" "$pkgdir/usr/lib/systemd/system/irda.service"
install -Dm644 etc/modules.conf.irda "$pkgdir/etc/modprobe.conf.irda"
}
|