PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56

# Maintainer: Jake Stanger <mail@jstanger.dev>

pkgname=ironbar-git
pkgver=0.18.0.r114.ge45a178
pkgrel=2
makedepends=('rust' 'cargo' 'git' 'openssl')

depends=(
  'gtk4' 
  'gtk4-layer-shell' 
  'lua51-lgi' 
  'libinput'
  'libpulse'
  'luajit'
)

optdepends=('ttf-font-nerd: for displaying text-based icons')

provides=('ironbar')
conflicts=('ironbar')
arch=('i686' 'x86_64' 'armv6h' 'armv7h')
pkgdesc="Customisable wlroots/sway bar written in rust"
license=('MIT')
source=('git+https://github.com/JakeStanger/ironbar')
url='https://ironb.ar'
md5sums=('SKIP')

# See: <https://ironb.ar/issues/921>
options=('!lto')

pkgver() {
    cd "$srcdir/ironbar"
    git describe --long --tags | sed 's/^v//;s/\([^-]*-g\)/r\1/;s/-/./g' 
}

build() {
    cd "$srcdir/ironbar"
    cargo build --release --locked

    mkdir -p "$srcdir/ironbar/target/completions"

    "$srcdir/ironbar/target/release/ironbar" --print-completions bash > "$srcdir/ironbar/target/completions/ironbar.bash"
    "$srcdir/ironbar/target/release/ironbar" --print-completions zsh >  "$srcdir/ironbar/target/completions/_ironbar"
    "$srcdir/ironbar/target/release/ironbar" --print-completions fish > "$srcdir/ironbar/target/completions/ironbar.fish"
}

package() {
  install -Dm 755 "$srcdir/ironbar/target/release/ironbar" "$pkgdir/usr/bin/ironbar"

  install -Dm 644 "$srcdir/ironbar/target/completions/ironbar.bash" "$pkgdir/usr/share/bash-completion/completions/ironbar"
  install -Dm 644 "$srcdir/ironbar/target/completions/_ironbar" "$pkgdir/usr/share/zsh/site-functions/_ironbar"
  install -Dm 644 "$srcdir/ironbar/target/completions/ironbar.fish" "$pkgdir/usr/share/fish/vendor_completions.d/ironbar.fish"

  install -Dm 644 "$srcdir/ironbar/LICENSE" "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
  install -Dm 644 "$srcdir/ironbar/ironbar.service" "${pkgdir}/usr/lib/systemd/user/ironbar.service"
}