PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50

# Maintainer: Chocobo1 <chocobo1 AT archlinux DOT net>

pkgname=irqbalance-git
pkgver=1.9.5.r3.g48ab93a
pkgrel=1
pkgdesc="A daemon to help balance the CPU load generated by interrupts across all of a systems CPUs"
arch=('i686' 'x86_64')
url="https://irqbalance.github.io/irqbalance/"
license=('GPL-2.0-or-later')
depends=('glibc' 'libcap-ng.so' 'libglib-2.0.so' 'libncursesw.so' 'libnl' 'libnuma.so' 'libsystemd.so')
makedepends=('git' 'meson' 'glib2' 'libcap-ng' 'ncurses' 'systemd')
provides=("irqbalance=$pkgver")
conflicts=('irqbalance')
backup=('etc/irqbalance.env')
source=("git+https://github.com/Irqbalance/irqbalance.git")
sha256sums=('SKIP')


prepare() {
  cd "irqbalance"

  sed \
    -e 's|/usr/sbin|/usr/bin|g' \
    -i "misc/irqbalance.service.in"
}

pkgver() {
  cd "irqbalance"

  git describe --long --tags | sed 's/^v//;s/\([^-]*-g\)/r\1/;s/-/./g'
}

build() {
  cd "irqbalance"

  meson setup \
    --buildtype=plain \
    --prefix="/usr" \
    --sbindir="bin" \
    -Ddefault_library="both" \
    "_build"
  meson compile -C "_build"
}

package() {
  cd "irqbalance"

  meson install -C "_build" --destdir "$pkgdir"
  mv "$pkgdir/usr/etc" "$pkgdir/etc"
}