PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51

# Maintainer: Muflone http://www.muflone.com/contacts/english/

pkgname=iscan-plugin-gt-s650
pkgver=1.1.0
pkgrel=1
pkgdesc="EPSON Image Scan! plugin for Epson Perfection V19 scanner"
arch=('i686' 'x86_64')
url="http://download.ebz.epson.net/dsc/search/01/search/?OSC=LX"
license=('custom:AVASYSPL')
depends=('iscan')
_plugin=${pkgname/iscan-plugin-/}
_iscan_ver=1.0.0
_plugin_rel=2
source_i686=("https://download2.ebz.epson.net/iscan/plugin/${_plugin}/deb/x86/iscan-${_plugin}-bundle-${_iscan_ver}.x86.deb.tar.gz")
source_x86_64=("https://download2.ebz.epson.net/iscan/plugin/${_plugin}/deb/x64/iscan-${_plugin}-bundle-${_iscan_ver}.x64.deb.tar.gz")
sha256sums_i686=('6f12a5d7b3c1a08a6c5f8762e1cff7ee89063eb73ec723f1822d3fa10c5b50f9')
sha256sums_x86_64=('d27e55652942f7c6e5f7f1b09296b742751c872e3963f8167e1f66fe360d9226')
install="${pkgname}.install"

if [ "$CARCH" = 'x86_64' ]
then
  _filearch=x64
  _debarch=amd64
else
  _filearch=x86
  _debarch=i386
fi

build() {
  cd "iscan-${_plugin}-bundle-${_iscan_ver}.${_filearch}.deb/plugins"
  bsdtar -xf ${pkgname}_${pkgver}-${_plugin_rel}_${_debarch}.deb
  bsdtar -xf data.tar.gz
  gzip -fkd "usr/share/doc/${pkgname}/NEWS.gz"
}

package() {
  cd "iscan-${_plugin}-bundle-${_iscan_ver}.${_filearch}.deb/plugins/usr"
  install -m 755 -d "${pkgdir}/usr/lib/iscan"
  install -m 644 -t "${pkgdir}/usr/lib/iscan" "lib/iscan/libiscan-plugin-gt-s650.so.0.0.0"
  ln -s libiscan-plugin-gt-s650.so.0.0.0 "${pkgdir}/usr/lib/iscan/libiscan-plugin-gt-s650.so"
  ln -s libiscan-plugin-gt-s650.so.0.0.0 "${pkgdir}/usr/lib/iscan/libiscan-plugin-gt-s650.so.0"

  install -m 755 -d "${pkgdir}/usr/share/iscan"
  install -m 644 -t "${pkgdir}/usr/share/iscan" "share/iscan/esfw010c.bin"

  install -m 755 -d "${pkgdir}/usr/share/doc/${pkgname}"
  install -m 644 -t "${pkgdir}/usr/share/doc/${pkgname}" "share/doc/${pkgname}"/{NEWS,README}

  install -m 755 -d "${pkgdir}/usr/share/licenses/${pkgname}"
  install -m 644 "share/doc/${pkgname}/AVASYSPL.en.txt" "${pkgdir}/usr/share/licenses/${pkgname}/AVASYSPL"
}