blob: 9f72d2efa8a73154475b35c653f08abc3c3fdc18 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
|
# Maintainer: Ondřej Hošek <ondra.hosek@gmail.com>
# Contributor: Allan McRae <allan@archlinux.org>
pkgname=isl-git
pkgver=0.20.52.g44534fc7
pkgrel=1
pkgdesc="Library for manipulating sets and relations of integer points bounded by linear constraints (development version)"
arch=('i686' 'x86_64')
url="http://isl.gforge.inria.fr/"
depends=('gmp')
makedepends=('clang' 'llvm')
license=('MIT')
options=('!libtool')
provides=('isl')
conflicts=('isl')
source=("${pkgname%-git}::git+http://repo.or.cz/isl.git")
sha256sums=('SKIP')
pkgver() {
cd "$srcdir/${pkgname%-git}"
git describe --always | sed -e 's|^isl-||' -e 's|-|.|g'
}
build() {
cd "$srcdir/${pkgname%-git}"
./autogen.sh
./configure --prefix=/usr --with-clang=system
make
}
check() {
cd "$srcdir/${pkgname%-git}"
make check
}
package() {
cd "$srcdir/${pkgname%-git}"
make -j1 DESTDIR="$pkgdir/" install
install -dm755 "$pkgdir/usr/share/gdb/auto-load/usr/lib/"
mv "$pkgdir"/{,/usr/share/gdb/auto-load/}usr/lib/libisl.so.19.1.0-gdb.py
install -Dm644 LICENSE "$pkgdir/usr/share/licenses/isl/LICENSE"
}
|