blob: 5426eda243b589d4345ea364e3078a0d4b339fa6 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
|
# Maintainer: Antoine Pietri <antoine.pietri@lrde.epita.fr>
# Maintainer: William Di Luigi <williamdiluigi@gmail.com>
pkgname=isolate
pkgver=1.5
pkgrel=1
pkgdesc="Sandbox for securely executing untrusted programs"
arch=('i686' 'x86_64')
url="https://github.com/ioi/isolate"
license=('GPL2')
depends=()
makedepends=('git' 'gcc' 'asciidoc')
provides=('isolate')
conflicts=('isolate-git')
install=$pkgname.install
source=("https://github.com/ioi/isolate/archive/v$pkgver.zip")
sha512sums=('38e3d7b8f10b7fab7faaa712c93339d936246cb615f9d7371275481b86f7b259c600e765a9f28b3f8bd1807ec89f3f4808c71bd5860790d63f9049ac8bda1cbc')
build() {
cd isolate-$pkgver
make PREFIX="/usr" VARPREFIX="/var" CONFIGDIR="/etc" isolate isolate.1
}
package() {
cd isolate-$pkgver
make PREFIX="$pkgdir/usr" VARPREFIX="$pkgdir/var" CONFIGDIR="$pkgdir/etc" install install-doc
# Patch the configuration file so that it uses a standard directory
sed -i "s|/var/local/lib/isolate|/var/lib/isolate|" $pkgdir/etc/isolate
# The isolate binary has the setuid bit set (to run as root without sudo)
# however we should let only the owner and the group be able to run it:
chmod o-x $pkgdir/usr/bin/isolate
}
|