blob: 54943c25fed493db658b94f0346544f65fba3d0f (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
|
# Maintainer: Carl Smedstad <carl.smedstad at protonmail dot com>
# Contributor: Jean-Francois Chevrette <jfchevrette@gmail.com>
# Contributor: Matthew Ellison <matt+aur@arroyonetworks.com>
pkgname=istio-bin
_pkgname=istio
pkgver=1.13.1
pkgrel=1
pkgdesc='An open platform to connect, manage, and secure microservices'
arch=('x86_64' 'aarch64' 'armv7h')
url='https://istio.io'
license=('Apache')
depends=('bash' 'glibc')
conflicts=("${_pkgname}")
provides=("${_pkgname}")
_source_base="https://github.com/istio/istio/releases/download/$pkgver"
source_x86_64=("$_source_base/istio-$pkgver-linux-amd64.tar.gz")
source_armv7h=("$_source_base/istio-$pkgver-linux-armv7.tar.gz")
source_aarch64=("$_source_base/istio-$pkgver-linux-arm64.tar.gz")
sha256sums_x86_64=('fc3ce898bca06af01e3e0d28cb7ff34c59c7878bf50e5c7c56ee28d44eb96f3f')
sha256sums_armv7h=('ee077551855a33c360cb696a4d4e8469cb72803ba1ba48269b4cb2cb959bad71')
sha256sums_aarch64=('1c11bf9b98b00e93f1ffdd276a27c566a5d9582fa7c92a88d83a270976dc7786')
package() {
cd "$srcdir/$_pkgname-$pkgver"
install -Dm755 "bin/istioctl" "$pkgdir/usr/bin/istioctl"
install -Dm644 "tools/_istioctl" "$pkgdir/usr/share/zsh/site-functions/_istioctl"
install -Dm644 "tools/istioctl.bash" "$pkgdir/usr/share/bash-completion/completions/istioctl"
install -Dm644 "LICENSE" "$pkgdir/usr/share/licenses/$_pkgname/LICENSE"
install -d "$pkgdir/usr/share/$_pkgname"
for d in manifests samples tools; do
cp -R "$d" "$pkgdir/usr/share/$_pkgname/"
done
}
|