blob: e5cae20a1156ac9798b3783dbb5b285e246ef6b8 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
|
# Maintainer: FrozenCow <frozencow@gmail.com>
pkgname=itch
pkgver=0.13.2
pkgrel=1
pkgdesc="The best way to play itch.io games."
arch=('i686' 'x86_64')
url="https://github.com/itchio/itch"
license=('MIT')
depends=('alsa-lib' 'libnotify' 'nss' 'gconf' 'gtk2' 'libxtst' 'desktop-file-utils' 'gtk-update-icon-cache' 'p7zip')
makedepends=('nodejs-babel-cli' 'sassc' 'electron' 'nodejs' 'nodejs-grunt-cli' 'npm')
options=('!strip')
install="itch.install"
source=("https://github.com/itchio/itch/archive/v${pkgver}.tar.gz")
sha256sums=('fd258ee8e5e32508f71daa626fe30f21b0fb0d95660cbc9adc2b2898a21fa118')
[ "$CARCH" = "i686" ] && _ELECTRON_ARCH=ia32
[ "$CARCH" = "x86_64" ] && _ELECTRON_ARCH=x64
prepare() {
cd "itch-${pkgver}"
export PYTHON=/usr/bin/python2
# Get dependencies
npm install
}
build() {
cd "$srcdir/itch-${pkgver}"
release/prepare.sh
release/generate-itch-desktop.sh
grunt -v "electron:linux-${_ELECTRON_ARCH}"
}
check() {
cd "$srcdir/itch-${pkgver}"
npm test
}
package() {
cd "$srcdir/itch-$pkgver"
install -d "$pkgdir/opt/itch"
cp -a "build/v$pkgver/itch-linux-$_ELECTRON_ARCH/." "${pkgdir}/opt/itch"
install -d "$pkgdir/usr/share/applications"
install -Dm644 release/itch.desktop "${pkgdir}/usr/share/applications/itch.desktop"
for icon in release/icons/icon*.png
do
iconsize="${icon#release/icons/icon}"
iconsize="${iconsize%.png}"
icondir="$pkgdir/usr/share/icons/hicolor/${iconsize}x${iconsize}/apps/"
install -d "${icondir}"
install -Dm644 "$icon" "$icondir/itch.png"
done
install -D -m644 LICENSE "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
install -Dm755 "release/itch.sh" "${pkgdir}/usr/bin/itch"
}
|