blob: 497e00c02c3dc70f31e41954842aafff473af5fc (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
|
# Maintainer: Fabio 'Lolix' Loli <lolix@disroot.org> -> https://github.com/FabioLolix
# Contributor: Paragoumba <paragoumba@protonmail.com>
# Contributor: Amos Wenger <amos@itch.io>
pkgname=itch-setup-bin
pkgver=1.29.0
pkgrel=1
pkgdesc="Installer for the itch.io desktop app"
arch=(x86_64)
url="https://itch.io/"
license=(MIT)
depends=(gtk3)
_itchver=26.13.0
source=("itch-${_itchver}.tar.gz::https://github.com/itchio/itch/archive/refs/tags/v${_itchver}.tar.gz"
"itch-setup-LICENSE::https://raw.githubusercontent.com/itchio/itch-setup/master/LICENSE"
'itch.desktop'
'itch.sh')
provides=(itch-setup)
conflicts=(itch-setup itch)
source_x86_64=("itch-setup-$(date +%F-%H)-amd64::https://itch.io/app/download?platform=linux")
sha256sums=('94843e035f4d41a0888e872da2cd100cea04cccd8a409c4e46a8a082fb92ec5b'
'd50905ab2e78d6ed3773959d6fb3c1c2fee724cf497f1c441cacb3765eac30ff'
'57e1c8ad285b89f3380cd028aa51e8083a8e4327cc5763d396caf607e905efcf'
'985cf842686598dd7e4e153f6fd7c9ee901fd200403893235e2974b108653bcf')
sha256sums_x86_64=('16e87c1ea4704724e9e07a950ce122990f5c5dc8db269ae342c34919aca1074b')
package() {
install -Dm755 itch-setup-*-amd64 "${pkgdir}/usr/bin/itch-setup"
install -Dm755 itch.sh "${pkgdir}/usr/bin/itch"
install -Dm644 itch.desktop -t "${pkgdir}/usr/share/applications/"
install -Dm644 itch-setup-LICENSE "$pkgdir/usr/share/licenses/$pkgname/LICENSE"
cd "itch-${_itchver}"
for icon in release/images/itch-icons/icon*.png
do
iconsize="${icon#release/images/itch-icons/icon}"
iconsize="${iconsize%.png}"
icondir="${pkgdir}/usr/share/icons/hicolor/${iconsize}x${iconsize}/apps/"
install -d "${icondir}"
install -Dm644 "$icon" "$icondir/itch.png"
done
}
|