blob: 8708920c44821fe8758fa7fdc7b06b1bb59bad6c (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
|
# Maintainer: Christian Rebischke <chris.rebischke@archlinux.org>
pkgname=iwd-git
pkgver=r2423.5c5bfbb
pkgrel=1
pkgdesc='Internet Wireless Daemon'
arch=('i686' 'x86_64')
url='https://git.kernel.org/cgit/network/wireless/iwd.git/'
license=('LGPL')
depends=('glibc' 'readline' 'libreadline.so')
makedepends=('git' 'python-docutils')
backup=('etc/iwd/main.conf')
provides=('iwd')
conflicts=('iwd')
source=('git+https://git.kernel.org/pub/scm/network/wireless/iwd.git'
'git+https://git.kernel.org/pub/scm/libs/ell/ell.git')
sha256sums=('SKIP' 'SKIP')
_gitname='iwd'
changelog=ChangeLog
install=iwd.install
pkgver() {
cd "${_gitname}"
printf "r%s.%s" "$(git rev-list --count HEAD)" "$(git rev-parse --short=7 HEAD)"
}
build() {
cd "${srcdir}/${_gitname}"
./configure --prefix=/usr \
--sysconfdir=/etc \
--localstatedir=/var \
--with-runstatedir=/run \
--libexecdir=/usr/lib/iwd \
--enable-wired \
--enable-ofono \
--enable-sim-hardcoded \
--enable-hwsim \
--disable-tools
make
}
package() {
cd "${srcdir}/${_gitname}"
make install DESTDIR="${pkgdir}"
install -Dm 644 README -t "${pkgdir}/usr/share/doc/${pkgname}"
}
# vim: set ts=2 sw=2 ft=sh noet:
|