blob: ac47727186c69f0711f60956ea10b6866d1edae5 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
|
# Maintainer: Christopher Arndt <aur -at- chrisarndt -dot- de>
_pkgname=jalv
pkgname="${_pkgname}-git"
pkgver=1.6.1.r443.3dc259e
pkgrel=1
pkgdesc="A simple but fully featured LV2 host for Jack"
arch=('i686' 'x86_64')
url="http://drobilla.net/software/${_pkgname}/"
license=('custom:ISC')
depends=('lilv' 'suil')
makedepends=('git' 'gtk2' 'gtk3' 'gtkmm' 'jack' 'python' 'qt4' 'qt5-base')
provides=("${_pkgname}")
conflicts=("${_pkgname}")
optdepends=('gtk2: Gtk+ 2.x frontend'
'gtk3: Gtk+ 3.x frontend'
'gtkmm: Gtk++ 2.x frontend'
'qt4: Qt 4.x frontend'
'qt5-base: Qt 5.x frontend')
source=("${_pkgname}::git+http://git.drobilla.net/${_pkgname}.git"
'autowaf::git+https://gitlab.com/drobilla/autowaf.git')
md5sums=('SKIP' 'SKIP')
pkgver() {
cd "${srcdir}/${_pkgname}"
local ver=`grep "^JALV_VERSION" wscript | cut -d "'" -f 2`
echo "$ver.r$(git rev-list --count HEAD).$(git rev-parse --short HEAD)"
}
prepare() {
cd "${srcdir}/${_pkgname}"
git submodule init
git config submodule.waflib.url "${srcdir}/autowaf"
git submodule update
}
build() {
cd "${srcdir}/${_pkgname}"
CXXFLAGS+=' -std=c++11'
python waf configure --prefix=/usr
python waf build $MAKEFLAGS
}
package() {
cd "${srcdir}/${_pkgname}"
python waf install --destdir="$pkgdir"
# license
install -Dm644 COPYING "$pkgdir/usr/share/licenses/$pkgname/LICENSE"
}
|