blob: b475033e8b7f468f72c2219cc196b32c9f8255e5 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
|
# Maintainer: Mark Wagie <mark dot wagie at tutanota dot com>
pkgname=jamesdsp-git
pkgver=2.4.r10.g01ba926
pkgrel=1
pkgdesc="An audio effect processor for PipeWire clients"
arch=('x86_64')
url="https://github.com/Audio4Linux/JDSP4Linux"
license=('GPL3')
depends=('glibmm' 'pipewire' 'qt5-svg')
makedepends=('git')
provides=("${pkgname%-git}")
conflicts=("${pkgname%-git}" 'jdsp4linux' 'jdsp4linux-gui' 'gst-plugin-jamesdsp')
replaces=('jdsp4linux-git' 'jdsp4linux-gui-git' 'gst-plugin-jamesdsp-git')
options=('debug')
source=('git+https://github.com/Audio4Linux/JDSP4Linux.git'
'git+https://github.com/ThePBone/EELEditor.git'
'git+https://github.com/ThePBone/GraphicEQWidget.git'
'git+https://github.com/ThePBone/FlatTabWidget.git'
'git+https://github.com/ThePBone/LiquidEqualizerWidget.git'
'jamesdsp.desktop')
sha256sums=('SKIP'
'SKIP'
'SKIP'
'SKIP'
'SKIP'
'c6496e6981471aa3f8d1593673991e422d243ff3efe595b3230de713588599c3')
pkgver() {
cd "$srcdir/JDSP4Linux"
git describe --long --tags | sed 's/\([^-]*-g\)/r\1/;s/-/./g'
}
prepare() {
cd "$srcdir/JDSP4Linux"
for submodule in EELEditor GraphicEQWidget FlatTabWidget LiquidEqualizerWidget; do
git submodule init
git config submodule.src/subprojects/"$submodule".url "$srcdir/$submodule"
git -c protocol.file.allow=always submodule update
done
mkdir -p build
}
build() {
cd "$srcdir/JDSP4Linux"
pushd build
qmake-qt5 ..
make
popd
}
package() {
cd "$srcdir/JDSP4Linux"
install -Dm755 build/src/jamesdsp -t "$pkgdir/usr/bin/"
install -Dm644 resources/icons/icon.png \
"$pkgdir/usr/share/pixmaps/jamesdsp.png"
install -Dm644 resources/icons/icon.svg \
"$pkgdir/usr/share/icons/hicolor/scalable/apps/jamesdsp.svg"
install -Dm644 "$srcdir/jamesdsp.desktop" -t "$pkgdir/usr/share/applications/"
}
|