PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73

# Maintainer: SelfRef <arch@selfref.dev>

_pkgbase=jan
pkgname=${_pkgbase}-git
pkgver=0.7.3.r43.g4957509
pkgrel=1
pkgdesc="An open source alternative to ChatGPT that runs 100% offline on your computer"
url="https://jan.ai/"
arch=('x86_64')
license=('Apache-2.0')
source=("$_pkgbase::git+https://github.com/menloresearch/jan.git")
sha256sums=('SKIP')
provides=("$_pkgbase")
conflicts=("$_pkgbase")
options=(!lto)
depends=(
	'gtk3'
	'webkit2gtk-4.1'
)
optdepends=(
	'libappindicator-gtk3: for tray icon support'
	'uv: for MCP servers based on Python'
	'npm: for MCP servers based on Node.js'
)
makedepends=(
	'git'
	'nvm'
	'yarn'
	'cargo'
	'libappindicator-gtk3'
)

_ensure_local_nvm() {
    which nvm >/dev/null 2>&1 && nvm deactivate && nvm unload
    export NVM_DIR="${srcdir}/.nvm"
    source /usr/share/nvm/init-nvm.sh || [[ $? != 1 ]]
}

pkgver() {
	cd "$_pkgbase"
	git describe --long --tags --abbrev=7 | sed 's/\([^-]*-g\)/r\1/;s/-/./g;s/^v//'
}

prepare() {
	cd "$_pkgbase"
	_ensure_local_nvm
	nvm install 20
	[ -f package.json ] && sed -i '/"build:tauri:linux"/ s/\.\/[^ ]*\.sh//g; /"build:tauri:linux"/ s/&& "/--bundles deb"/g' package.json
}

build() {
	cd "$_pkgbase"
	_ensure_local_nvm
	export YARN_CACHE_FOLDER="$srcdir"/yarn-cache
	export RUSTUP_TOOLCHAIN=stable

	rm -rf src-tauri/target/release/bundle/deb
	make build
}

package() {
	cd "$_pkgbase"
	install -Dm644 LICENSE "$pkgdir/usr/share/licenses/$_pkgbase/LICENSE"

	cd src-tauri/target/release/bundle/deb/Jan_*/data/usr
	install -Dm755 bin/Jan -t "$pkgdir"/usr/bin

	install -dm755 "$pkgdir"/usr/share
	cp -r share/* "$pkgdir"/usr/share

	install -dm755 "$pkgdir"/usr/lib
	cp -r lib/* "$pkgdir"/usr/lib
}