blob: 2bd32a23c3ac071186059591a3b023f1fe1b832b (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
|
# Maintainer: GrayJack <gr41.j4ck@gmail.com>
_pkgname=janet
pkgname=janet-lang-git
pkgver=1.35.2.r4352.771956b5
pkgrel=1
pkgdesc="A dynamic Lisp dialect and bytecode vm"
arch=('arm' 'armv6h' 'armv7h' 'i686' 'x86_64' 'aarch64')
url="https://janet-lang.org/"
license=('MIT')
depends=()
makedepends=('git')
provides=('janet' 'jpm' 'janet-lang')
conflicts=('janet-lang')
source=("git+https://github.com/janet-lang/janet.git" "git+https://github.com/janet-lang/jpm" "default_config.janet")
sha256sums=('SKIP'
'SKIP'
'7fb56585e6027ea800920a364acd73b49205298dcf887a4ee71fb65125c4539f')
options=('staticlibs')
pkgver() {
cd "${srcdir}/${_pkgname}"
# Get the version number.
printf "$(grep 'JANET_VERSION ' src/conf/janetconf.h|head -n1|cut -d\" -f2|cut -d\- -f1).r%s.%s" "$(git rev-list --count HEAD)" "$(git rev-parse --short HEAD)"
}
build() {
cd "${srcdir}/${_pkgname}"
CFLAGS+=" -fPIC"
LDFLAGS+=" -rdynamic"
make PREFIX="/usr" $janet_build -j7
make PREFIX="/usr" build/janet.pc
make PREFIX="/usr" docs
}
package() {
cd "${srcdir}/${_pkgname}"
install -Dt "${pkgdir}"/usr/bin build/janet
install -Dm644 -t "${pkgdir}"/usr/include/janet build/janet.h
install -Dm644 -t "${pkgdir}"/usr/lib build/libjanet.a build/libjanet.so
ln -s libjanet.so "${pkgdir}"/usr/lib/libjanet.so.$pkgver
install -Dm644 "build/janet.pc" "${pkgdir}"/usr/lib/pkgconfig/janet.pc
install -Dm644 -t "${pkgdir}"/usr/share/man janet.1
install -dm755 "${pkgdir}"/usr/share/janet
cp -a examples "${pkgdir}"/usr/share/janet
install -Dm644 build/doc.html "${pkgdir}"/usr/share/doc/janet/doc.html
install -Dm644 -t "${pkgdir}"/usr/lib/janet tools/.keep
cd "${srcdir}/jpm"
install -Dt "${pkgdir}"/usr/bin jpm/jpm
install -Dm644 -t "${pkgdir}"/usr/lib/janet/jpm jpm/*
install -Dm644 -t "${pkgdir}"/usr/share/man jpm.1
install -Dm644 -t "${pkgdir}"/usr/share/janet/jpm/configs configs/*
install -m644 -T "${srcdir}"/default_config.janet "${pkgdir}"/usr/lib/janet/jpm/default-config.janet
}
|