blob: 4cfe4f9ae71e0080c6e5a9e9c4752faf46da9db2 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
|
# Maintainer: Marcel Joss <marceljoss@hotmail.ch>
# Contributor: Felix Golatofski <contact@xdfr.de>
# Contributor: M A <morealaz at gmail dot com>
pkgname='java-openjdk-bin'
_majorver='25'
_fullver="${_majorver}.0.2"
_buildver='10'
_hash='b1e0dfa218384cb9959bdcb897162d4e'
pkgver="${_fullver}.u${_buildver}"
pkgrel=1
pkgdesc="Java OpenJDK ${_fullver} Oracle Build."
arch=('x86_64' 'aarch64')
url="https://jdk.java.net/${_majorver}"
license=('GPL2')
depends=('java-environment-common' 'java-runtime-common' 'ca-certificates-utils' 'nss')
provides=(
"java-environment=${_majorver}"
"java-environment-openjdk=${_majorver}"
"java-runtime=${_majorver}"
"java-runtime-openjdk=${_majorver}"
"java-runtime-headless=${_majorver}"
"java-runtime-headless-openjdk=${_majorver}"
)
_sourcePrefix="https://download.java.net/java/GA/jdk${_fullver}/${_hash}/${_buildver}/GPL/openjdk-${_fullver}_linux-"
_sourceSuffix="_bin.tar.gz"
source_x86_64=("${_sourcePrefix}x64${_sourceSuffix}")
source_aarch64=("${_sourcePrefix}aarch64${_sourceSuffix}")
sha256sums_x86_64=('555ce0821e4fe175ea50d54518cd6fbece9663c1998de529bc6ce429534457df')
sha256sums_aarch64=('671208d205e70c9805da45a483f670d49dd64654990a7b7223ccffb2abb070dd')
_jvmdir="usr/lib/jvm/java-${_majorver}-openjdk-bin"
package() {
# Install
install -d "${pkgdir}/${_jvmdir}"
cd jdk-${_fullver}
cp -a bin include jmods lib release "${pkgdir}/${_jvmdir}/"
# Link JKS keystore from ca-certificates-utils
rm -f "${pkgdir}/${_jvmdir}/lib/security/cacerts"
ln -sf /etc/ssl/certs/java/cacerts "${pkgdir}/${_jvmdir}/lib/security/cacerts"
# Legal
install -d "${pkgdir}/usr/share/licenses/java${_majorver}-openjdk"
cp -a legal "${pkgdir}/usr/share/licenses/java${_majorver}-openjdk/"
ln -s /usr/share/licenses/java${_majorver}-openjdk "${pkgdir}/${_jvmdir}/legal"
# Conf
install -d "${pkgdir}/etc"
cp -r conf "${pkgdir}/etc/java${_majorver}-openjdk"
ln -s /etc/java${_majorver}-openjdk "${pkgdir}/${_jvmdir}/conf"
}
# vim:set ts=4 sw=4 et:
|