blob: 6cc3f6d14ade51e97a02f54421f4d063e8f58f6e (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
|
# Maintainer: Stefan Zobel <stefan dot zobel at gmail dot com>
# Contributor: Jamie Magee <jamie dot magee at gmail dot com>
# Contributor: Mohammadreza Abdollahzadeh <morealaz at gmail dot com>
pkgname=java-openjdk-ea-bin
_majorver=22
_buildver=35
pkgver=${_majorver}b${_buildver}
pkgrel=1
_JARCH='x64'
case "${CARCH}" in
x86_64) _JARCH='x64';;
aarch64) _JARCH='aarch64';;
esac
pkgdesc="Java OpenJDK ${_majorver} Early-Access Build"
arch=('x86_64' 'aarch64')
url="https://jdk.java.net/${_majorver}"
license=('GPL2')
depends=(
'java-environment-common>=3' 'java-runtime-common>=3'
'ca-certificates-utils' 'nss' 'libxrender' 'libxtst'
'alsa-lib' 'freetype2'
)
provides=(
"java-environment=${_majorver}"
"java-environment-openjdk=${_majorver}"
"java-runtime=${_majorver}"
"java-runtime-openjdk=${_majorver}"
"java-runtime-headless=${_majorver}"
"java-runtime-headless-openjdk=${_majorver}"
)
#source=("https://download.java.net/java/early_access/jdk${_majorver}/${_buildver}/GPL/openjdk-${_majorver}-ea+${_buildver}_linux-${_JARCH}_bin.tar.gz")
source=("https://download.java.net/java/GA/jdk22/830ec9fcccef480bb3e73fb7ecafe059/35/GPL/openjdk-22_linux-${_JARCH}_bin.tar.gz")
if [[ $_JARCH == "x64" ]]; then
sha256sums=('37b0e1d93e9b6478824c21753f2e8445c8caad885a2245f393b35658be1695b3')
else
sha256sums=('5bc8c3ea634bf3be8a275c789dabbaa3e68eb639ee920b6fbce1b2236082086d')
fi
_eaname=java-${_majorver}-openjdk
_jvmdir=/usr/lib/jvm/${_eaname}
package() {
# Install
install -d "${pkgdir}${_jvmdir}"
cd jdk-${_majorver}
cp -a bin include jmods lib release "${pkgdir}${_jvmdir}/"
# Link JKS keystore from ca-certificates-utils
rm -f "${pkgdir}${_jvmdir}/lib/security/cacerts"
ln -sf /etc/ssl/certs/java/cacerts "${pkgdir}${_jvmdir}/lib/security/cacerts"
# Legal
install -d "${pkgdir}/usr/share/licenses/${_eaname}"
cp -a legal "${pkgdir}/usr/share/licenses/${_eaname}/"
ln -s /usr/share/licenses/${_eaname} "${pkgdir}${_jvmdir}/legal"
# Conf
install -d "${pkgdir}/etc"
cp -r conf "${pkgdir}/etc/${_eaname}"
ln -s /etc/${_eaname} "${pkgdir}${_jvmdir}/conf"
}
# vim:set ts=2 sw=2 et:
|