blob: 1837e86dadf4d3716c1819ae1b45ec873ad49d96 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
|
# Maintainer: Levente Polyak <anthraxx[at]archlinux[dot]org>
# Maintainer: Frederik Schwan <freswa at archlinux dot org>
# Contributor: Maxime Gauduin <alucryd@archlinux.org>
# Contributor: Guillaume Alaux <guillaume@archlinux.org>
# Contributor: William Gathoye <william + archlinux at gathoye dot be>
# Contributor: Emanuel Couto <emanuel dot amaral dot couto at gmail dot com>
# Contributor: Richard Jackson <rdjack21 at gmail dot com>
# Contributor: Tinx <arch at tinx dot eu>
# Contributor: Jens Kapitza <j dot kapitza at schwarze-allianz dot de>
# Contributor: Olli <olli at coderkun dot de>
pkgbase=java-openjfx
pkgname=(
java-openjfx
java-openjfx-doc
java-openjfx-src
)
pkgver=18.0.1.u2
pkgrel=1
pkgdesc="Java OpenJFX 17 client application platform (open-source implementation of JavaFX)"
arch=(x86_64)
url=https://wiki.openjdk.java.net/display/OpenJFX/Main
license=(custom)
makedepends=(
alsa-lib
ant
cairo
cmake
ffmpeg4.4
freetype2
gdk-pixbuf2
glib2
gperf
gradle
gtk2
gtk3
java-environment-openjdk=18
libgl
libx11
libxtst
pango
python
qt5-base
ruby
unzip
webkit2gtk
zip
)
source=(
https://github.com/openjdk/jfx/archive/refs/tags/${pkgver//.u/+}.tar.gz
# ${pkgname}-${pkgver}.tar.gz::https://github.com/openjdk/jfx${pkgver%%.*}u/archive/refs/tags/${pkgver//.u/+}.tar.gz
gradle.properties
java-openjfx-flags.patch
java-openjfx-no-xlocale.patch
java-openjfx-gstreamer-lite-gcc10-compat.patch
)
b2sums=('2ae577a5321b982989a1cd41e0a16906147d0620a4b6c33359da58db75bffc6b2e3a263f764036d9b37c492f002eeacf576cdb3740a75da7a4cd699393986fd3'
'a77fd8814a5978827de01a652f7b945f3439df04606434ced8998c8d77a82985292490e6965299aeb52f9da3d8069b4091d75519bd4ec8a15f70bc6d28b13498'
'2bc0cd6945ac33c882d56beb8abaa26bde038ebf25badb6e8f8af301449e7d56c2f795159d57ef2ccc8f5504bb8466e00445e65ff09519d9c6132e1b7dc6f4b5'
'13216615c01b8d48d17889ffa22668c38568870d83ab30c542eb5b5620db305f02efb1acb99d9b5e89eb0a73a134bb336cb301f4de4e8855cae50efb099e384e'
'119fa1cc5da2cdefa22bbe9b6f76581faa74e05fa7b6e5576470fc0251c6e257f122fbba03754cc01f7c7251145cfa1cab4ffc2f9d59ff0c175a121e943a0f64')
prepare() {
cd jfx-${pkgver//.u/-}
# cd jfx${pkgver%%.*}u-${pkgver//.u/-}
ln -sf ../gradle.properties .
patch -Np1 -i ../java-openjfx-flags.patch
patch -Np1 -i ../java-openjfx-no-xlocale.patch
patch -Np1 -i ../java-openjfx-gstreamer-lite-gcc10-compat.patch
sed 's|, "-Werror"||g' -i buildSrc/linux.gradle
}
build() {
cd jfx-${pkgver//.u/-}
# cd jfx${pkgver%%.*}u-${pkgver//.u/-}
# build against ffmpeg4.4
export PKG_CONFIG_PATH='/usr/lib/ffmpeg4.4/pkgconfig'
gradle zips
}
package_java-openjfx() {
depends=(
java-runtime-openjdk=${pkgver%%.*}
libgl
libx11
libxtst
)
optdepends=(
'ffmpeg4.4: Media support',
'gtk2: GTK2 support',
'gtk3: GTK3 support',
'webkit2gtk: Web support'
)
provides=(java-openjfx=${pkgver%%.*})
cd jfx-${pkgver//.u/-}
# cd jfx${pkgver%%.*}u-${pkgver//.u/-}
install -dm 755 "${pkgdir}"/usr/{lib/jvm/java-${pkgver%%.*}-openjdk,share/licenses}
cp -dr --no-preserve=ownership build/sdk/lib "${pkgdir}"/usr/lib/jvm/java-${pkgver%%.*}-openjdk/
cp -dr --no-preserve=ownership build/jmods "${pkgdir}"/usr/lib/jvm/java-${pkgver%%.*}-openjdk/
cp -dr --no-preserve=ownership build/sdk/legal "${pkgdir}"/usr/share/licenses/java-openjfx
}
package_java-openjfx-doc() {
cd jfx-${pkgver//.u/-}
# cd jfx${pkgver%%.*}u-${pkgver//.u/-}
install -dm 755 "${pkgdir}"/usr/share/{doc,licenses}
cp -dr --no-preserve=ownership build/javadoc "${pkgdir}"/usr/share/doc/java-openjfx
ln -s java-openjfx "${pkgdir}"/usr/share/licenses/java-openjfx-doc
}
package_java-openjfx-src() {
cd jfx-${pkgver//.u/-}
# cd jfx${pkgver%%.*}u-${pkgver//.u/-}
install -dm 755 "${pkgdir}"/usr/{lib/jvm/java-${pkgver%%.*}-openjdk,share/licenses}
install -m 644 build/sdk/src.zip "${pkgdir}"/usr/lib/jvm/java-${pkgver%%.*}-openjdk/javafx-src.zip
ln -s java-openjfx "${pkgdir}"/usr/share/licenses/java-openjfx-src
}
# vim: ts=2 sw=2 et:
|