blob: 183ae958d1573944602e93b1c49deb4c25028ef8 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
|
# Maintainer: L B <leobaldin dot 2000 at gmail dot com>
pkgname=java-openjfx-bin
_majorver=14
pkgver=14
pkgrel=1
pkgdesc="Java OpenJFX ${_majorver} client application platform (Gluon build)."
arch=('x86_64')
url='https://openjfx.io/'
license=('GPL2')
depends=('ffmpeg' 'gstreamer' 'java-environment>=11' 'libxtst' 'qt5-base' 'webkit2gtk')
provides=("java-openjfx=${_majorver}")
conflicts=("java${_majorver}-openjfx")
source=("https://download2.gluonhq.com/openjfx/${_majorver}/openjfx-${_majorver}_linux-x64_bin-sdk.zip"
"https://download2.gluonhq.com/openjfx/${_majorver}/openjfx-${_majorver}_linux-x64_bin-jmods.zip"
"https://download2.gluonhq.com/openjfx/${_majorver}/openjfx-${_majorver}-javadoc.zip")
sha256sums=('dc0ce35ba41956b08fe62e2db9b8cf6dd80ba21716564d78ad652ddd945d6dbd'
'07e76608102dacc96c95a7a8d18f844df0c33bd8fbda8675d7c158cc642b119c'
'5c7d03bd6dde6f9d0f185fb9c1dfe8ed70fab0d21eef131856fcedec9074986f')
_jvmdir=usr/lib/jvm/java-${_majorver}-openjdk
package() {
# Install
install -d "${pkgdir}/${_jvmdir}"
cp -a "javafx-sdk-${_majorver}/lib" "${pkgdir}/${_jvmdir}/"
mv "${pkgdir}/${_jvmdir}/lib/src.zip" "${pkgdir}/${_jvmdir}/lib/javafx-src.zip"
# Legal
install -d "${pkgdir}/usr/share/licenses/java${_majorver}-openjdk"
cp -a "javafx-sdk-${_majorver}/legal" "${pkgdir}/usr/share/licenses/java${_majorver}-openjdk/"
# Jmods
install -d "${pkgdir}/${_jvmdir}/jmods"
cp -a "javafx-jmods-${_majorver}/"* "${pkgdir}/${_jvmdir}/jmods/"
# Docs
install -d "${pkgdir}/usr/share/doc/java${_majorver}-openjfx"
cp -a "javafx-${_majorver}-javadoc/"* "${pkgdir}/usr/share/doc/java${_majorver}-openjfx/"
}
# vim:set ts=4 sw=4 et:
|