blob: 93dbe324e69c0281863d33f05abf2e465a7cb477 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
|
# Maintainer: Mohammadreza Abdollahzadeh <morealaz[at]gmail[dot]com>
# Contributer: Felix Golatofski <contact@xdfr.de>
# Contributer: Jamie Magee <jamie dot magee at gmail dot com>
pkgname=java-openjfx-ea-bin
_majorver=18
_buildver=3
pkgver=${_majorver}rc${_buildver}
pkgrel=1
pkgdesc="Java OpenJFX ${_majorver} Early-Access Build."
arch=('x86_64')
url='https://openjfx.io/'
license=('GPL2')
depends=('java-openjdk-ea-bin' 'gstreamer' 'libxtst' 'webkit2gtk' 'ffmpeg' 'qt5-base')
provides=("java-openjfx=${_majorver}")
conflicts=("java${_majorver}-openjfx")
source=("https://download2.gluonhq.com/openjfx/${_majorver}/openjfx-${_majorver}-ea+${_buildver}_linux-x64_bin-sdk.zip"
"https://download2.gluonhq.com/openjfx/${_majorver}/openjfx-${_majorver}-ea+${_buildver}_linux-x64_bin-jmods.zip"
"https://download2.gluonhq.com/openjfx/${_majorver}/openjfx-${_majorver}-ea+${_buildver}-javadoc.zip")
sha256sums=('08c1ed69e6e8dffc2b312edb12184e544839b1db55556bcb30c3880b4e3700ec'
'75262d9d8e11f623c88262434b61e365d9fcd2a711b41a4acb077b6140bbcb33'
'5f5c706704e6f97a4af5b57f50af8ef1792ccc7c2baf8f6df7478508df0aff91')
_jvmdir=usr/lib/jvm/java-${_majorver}-openjdk
package() {
# Install
install -d "${pkgdir}/${_jvmdir}"
cp -a "javafx-sdk-${_majorver}/lib" "${pkgdir}/${_jvmdir}/"
install -Dm 644 "javafx-sdk-${_majorver}/src.zip" "${pkgdir}/${_jvmdir}/lib/javafx-src.zip"
# Legal
install -d "${pkgdir}/usr/share/licenses/java${_majorver}-openjdk"
cp -a "javafx-sdk-${_majorver}/legal" "${pkgdir}/usr/share/licenses/java${_majorver}-openjdk/"
# Jmods
install -d "${pkgdir}/${_jvmdir}/jmods"
cp -a "javafx-jmods-${_majorver}/"* "${pkgdir}/${_jvmdir}/jmods/"
# Docs
install -d "${pkgdir}/usr/share/doc/java${_majorver}-openjfx"
cp -a "javafx-${_majorver}-javadoc/"* "${pkgdir}/usr/share/doc/java${_majorver}-openjfx/"
}
# vim:set ts=4 sw=4:
|