blob: 848546fa9c182ba2b70887d720ffba49211e063b (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
|
# Maintainer: Stipe Kotarac <stipe@kotarac.net>
pkgname=jay
pkgver=1.14.0
pkgrel=1
pkgdesc='A Wayland Compositor'
arch=('x86_64')
license=(GPL-3.0-only)
url='https://github.com/mahkoh/jay'
provides=(
wayland-compositor
)
depends=(
cairo
gcc-libs
glib2
glibc
libinput
libudev.so=1
libvulkan.so=1
mesa
pango
)
optdepends=(
'sqlite: session management'
'xdg-desktop-portal: portal support'
'xorg-xwayland: X11 support'
)
makedepends=(
cargo
cmake
)
options=(!lto)
source=("$pkgname-$pkgver.tar.gz::https://github.com/mahkoh/jay/archive/v$pkgver.tar.gz")
install=jay.install
sha512sums=('20e434a84b48b8bf9fa8142e4acec2115be12504cd21bb9f81574cdca4336f5b35752a27a6bf1d1ea4741807290cc65860744a553afcf990c20b94434e515faf')
prepare() {
cd $pkgname-$pkgver/
export RUSTUP_TOOLCHAIN=stable
cargo fetch --locked --target "$(rustc -vV | sed -n 's/host: //p')"
}
build() {
cd $pkgname-$pkgver/
export RUSTUP_TOOLCHAIN=stable
cargo build --frozen --release
}
check() {
cd $pkgname-$pkgver/
export RUSTUP_TOOLCHAIN=stable
cargo test --frozen --release
}
package() {
cd $pkgname-$pkgver/
install -D -m755 -s target/release/jay $pkgdir/usr/bin/jay
install -D -m644 etc/jay.portal $pkgdir/usr/share/xdg-desktop-portal/portals/jay.portal
install -D -m644 etc/jay-portals.conf $pkgdir/usr/share/xdg-desktop-portal/jay-portals.conf
mkdir -p $pkgdir/usr/share/zsh/site-functions/
target/release/jay generate-completion zsh > $pkgdir/usr/share/zsh/site-functions/_jay
mkdir -p $pkgdir/usr/share/bash-completion/completions/
target/release/jay generate-completion bash > $pkgdir/usr/share/bash-completion/completions/jay
mkdir -p $pkgdir/usr/share/fish/vendor_completions.d/
target/release/jay generate-completion fish > $pkgdir/usr/share/fish/vendor_completions.d/jay.fish
}
|