blob: 7ac82463c8f58012f720935967d650d4b594441a (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
|
# Maintainer: M A <morealaz at gmail dot com>
pkgname=jdk-openj9-bin
_jdkver=13
_openj9ver=0.18.0
_majorver=${_jdkver}.0.2
_buildvershort=8
_buildver=${_buildvershort}_openj9-${_openj9ver}
pkgver=${_majorver}b${_buildver//-/_}
pkgrel=4
pkgdesc="Eclipse (former IBM) OpenJ9 with latest GA release of openjdk (jdk${_jdkver})"
arch=('x86_64')
url="https://adoptopenjdk.net/index.html?variant=openjdk${_jdkver}&jvmVariant=openj9"
license=('GPL2')
depends=('ca-certificates-utils' 'java-environment-common' 'java-runtime-common' 'nss')
provides=(
"java-environment=${_jdkver}"
"java-environment-openjdk=${_jdkver}"
"java-runtime=${_jdkver}"
"java-runtime-openjdk=${_jdkver}"
"java-runtime-headless=${_jdkver}"
"java-runtime-headless-openjdk=${_jdkver}"
)
conflicts=("jdk${_jdkver}-openj9-bin" "jdk${_jdkver}-openj9")
options=(!strip)
source=("https://github.com/AdoptOpenJDK/openjdk${_jdkver}-binaries/releases/download/jdk-${_majorver}%2B${_buildver}/OpenJDK${_jdkver}U-jdk_x64_linux_openj9_${_majorver}_${_buildver}.tar.gz")
sha256sums=('aeecf6d30d0c847db81d07793cf97e5dc44890c29366d7d9f8f9f397f6c52590')
_jvmdir=usr/lib/jvm/java-${_jdkver}-j9
package() {
# Install
install -d "${pkgdir}/${_jvmdir}"
cd jdk-${_majorver}+${_buildvershort}
cp -a bin demo include jmods lib release "${pkgdir}/${_jvmdir}/"
# Link JKS keystore from ca-certificates-utils
rm -f "${pkgdir}/${_jvmdir}/lib/security/cacerts"
ln -sf /etc/ssl/certs/java/cacerts "${pkgdir}/${_jvmdir}/lib/security/cacerts"
# Legal
install -d "${pkgdir}/usr/share/licenses/java${_jdkver}-j9"
cp -a legal "${pkgdir}/usr/share/licenses/java${_jdkver}-j9/"
ln -s /usr/share/licenses/java${_jdkver}-j9 "${pkgdir}/${_jvmdir}/legal"
# Conf
install -d "${pkgdir}/etc"
cp -r conf "${pkgdir}/etc/java${_jdkver}-j9"
ln -s /etc/java${_jdkver}-j9 "${pkgdir}/${_jvmdir}/conf"
# Man pages
for f in man/man1/*; do
install -Dm 644 "${f}" "${pkgdir}/usr/share/${f/\.1/-openjdk${_jdkver}-j9.1}"
done
ln -s /usr/share/man "${pkgdir}/${_jvmdir}/man"
}
# vim:set ts=4 sw=4 et:
|