blob: 293c9203cefcc5c9abf3b01165dd3a8e91552eb8 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
|
# Maintainer: Chris Severance aur.severach AatT spamgourmet.com
# Contributor: Det <nimetonmaili g-mail>
_pkgname=jdk
pkgname=jdk10
pkgver=10.0.2
_major=${pkgver/.*}
_build=13
_hash=19aef61b38124481863b1413dce1855f
_jname=${_pkgname}${_major}
pkgrel=1
pkgdesc="Oracle Java $_major Development Kit (public release - end of support)"
arch=('x86_64')
url="http://www.oracle.com/technetwork/java/javase/downloads/index.html"
license=('custom:Oracle')
depends=('ca-certificates-java' 'hicolor-icon-theme' 'java-environment-common' 'java-runtime-common' 'nss' 'xdg-utils')
optdepends=('alsa-lib: for basic sound support'
'eclipse-java: to use "Oracle Java Mission Control" plugins in Eclipse'
'gtk2: for Gtk+ look and feel (desktop)')
provides=("java-runtime=$_major" "java-runtime-headless=$_major" "java-web-start=$_major" "java-environment=$_major"
"java-runtime-jre=$_major" "java-runtime-headless-jre=$_major" "java-web-start-jre=$_major" "java-environment-jdk=$_major"
"java-openjfx=$_major" "$_jname")
conflicts=("$_jname")
_jvmdir=/usr/lib/jvm/java-$_major-$_pkgname
backup=("etc/java-$_jname/management/jmxremote.access"
"etc/java-$_jname/management/management.properties"
"etc/java-$_jname/security/java.policy"
"etc/java-$_jname/security/java.security"
"etc/java-$_jname/security/javaws.policy"
"etc/java-$_jname/logging.properties"
"etc/java-$_jname/net.properties"
"etc/java-$_jname/sound.properties")
options=('!strip') # JDK debug-symbols
install=$pkgname.install
source=(
#"http://download.oracle.com/otn-pub/java/jdk/${pkgver}+${_build}/${_hash}/${_pkgname}-${pkgver}_linux-x64_bin.tar.gz"
"file://${_pkgname}-${pkgver}_linux-x64_bin.tar.gz"
'jconsole.desktop'
'jmc.desktop'
'policytool.desktop'
)
md5sums=('1cc0fa1d7f059978ae22a688dabcdc0b'
'ed1e8801db16b149247819c68fda97b1'
'0a3c4277ac6aec5c633af98d54986fa9'
'da29ac8f2d6b813ada985f6ee898005e')
sha256sums=('6633c20d53c50c20835364d0f3e172e0cbbce78fff81867488f22a6298fa372b'
'7fd81eced792aa76dac697b3daaa5d2699b15e8c6768ed4690a331e9f616b034'
'bef07cdacef3e25137ac6ec394f09bb683c3ceb30b894f4b0c5ea40b0f87e4d5'
'79fdffd1c3d6c0826a95d21e59392213c3a2e32709909629cfb4d222d349f2e1')
#DLAGENTS=('http::/usr/bin/curl -fLC - --retry 3 --retry-delay 3 -b oraclelicense=a -o %o %u')
package() {
cd $_pkgname-$pkgver
msg2 "Creating directory structure..."
install -d "$pkgdir"/etc/.java/.systemPrefs
install -d "$pkgdir"/usr/lib/jvm/java-$_major-$_pkgname/bin
install -d "$pkgdir"/usr/lib/mozilla/plugins
install -d "$pkgdir"/usr/share/licenses/java$_major-$_pkgname
msg2 "Removing redundancies..."
rm -r lib/desktop/icons/HighContrast
rm -r lib/desktop/icons/HighContrastInverse
rm -r lib/desktop/icons/LowContrast
rm lib/fontconfig.*.bfc
rm lib/fontconfig.*.properties.src
msg2 "Moving contents..."
mv * "$pkgdir"/$_jvmdir
# Cd to the new playground
cd "$pkgdir"/$_jvmdir
msg2 "Fixing directory structure..."
# Create a placeholder 'jre' link
ln -s . jre
# Fix bundled .desktops
sed -e "s|Exec=|Exec=$_jvmdir/bin/|" \
-e "s|.png|-$_jname.png|" \
-i lib/desktop/applications/*
# Move .desktops + icons to /usr/share
mv lib/desktop/* "$pkgdir"/usr/share/
install -m644 "$srcdir"/*.desktop "$pkgdir"/usr/share/applications/
# Suffix .desktops + icons (sun-jcontrol.png -> sun-jcontrol-$_jname.png)
for i in $(find "$pkgdir"/usr/share/ -type f); do
rename -- "." "-$_jname." $i
done
# Write versions to .desktops + .install
sed -i "s/<version>/$_major/" "$pkgdir"/usr/share/applications/* "$startdir"/$pkgname.install
# Link missing icons
for i in $(find "$pkgdir"/usr/share/icons/ -name "sun-jcontrol-$_jname.png" -type f); do
ln -s "sun-jcontrol-$_jname.png" "${i/jcontrol/java}"
ln -s "sun-jcontrol-$_jname.png" "${i/jcontrol/javaws}"
done
# Move confs to /etc and link back to /usr: /usr/lib/jvm/java-$_jname/conf -> /etc
for sub_path in $(find conf/ -type f); do
# New location
new_etc_path="/etc/java-$_jname/${sub_path/conf\/}"
# Move & link
install -Dm644 "$sub_path" "$pkgdir/$new_etc_path"
ln -sf "$new_etc_path" "$sub_path"
done
# Link NPAPI plugin
ln -sf $_jvmdir/lib/libnpjp2.so "$pkgdir"/usr/lib/mozilla/plugins/libnpjp2-$_jname.so
# Replace JKS keystore with 'ca-certificates-java'
ln -sf /etc/ssl/certs/java/cacerts lib/security/cacerts
# Move & link licenses
mv legal/ "$pkgdir"/usr/share/licenses/java$_major-$_pkgname/
ln -sf /usr/share/licenses/java$_major-$_pkgname/ "$pkgdir"/usr/share/licenses/$pkgname
msg2 "Enabling copy+paste in unsigned applets..."
# Copy/paste from system clipboard to unsigned Java applets has been disabled since 6u24:
# - https://blogs.oracle.com/kyle/entry/copy_and_paste_in_java
# - http://slightlyrandombrokenthoughts.blogspot.com/2011/03/oracle-java-applet-clipboard-injection.html
_line=$(awk '/permission/{a=NR}; END{print a}' "$pkgdir"/etc/java-$_jname/security/java.policy)
sed "$_line a\\\\n \
// (AUR) Allow unsigned applets to read system clipboard, see:\n \
// - https://blogs.oracle.com/kyle/entry/copy_and_paste_in_java\n \
// - http://slightlyrandombrokenthoughts.blogspot.com/2011/03/oracle-java-applet-clipboard-injection.html\n \
permission java.awt.AWTPermission \"accessClipboard\";" \
-i "$pkgdir"/etc/java-$_jname/security/java.policy
}
|