blob: d1e90679cb0c5650a10165f50a518b207461b1df (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
|
# Maintainer: Luca Weiss <luca (at) z3ntu (dot) xyz>
# Contributor: Maxime Gauduin <alucryd@archlinux.org>
# Contributor: Daniel Seymour <dannyseeless@gmail.com>
pkgname=jellyfin
pkgver=10.2.0
pkgrel=1
pkgdesc='The Free Software Media System'
arch=('i686' 'x86_64' 'armv6h')
url='https://github.com/jellyfin/jellyfin'
license=('GPL2')
depends=('dotnet-runtime' 'ffmpeg' 'imagemagick' 'sqlite')
makedepends=('dotnet-sdk')
source=("$pkgname-$pkgver.tar.gz::https://github.com/jellyfin/jellyfin/archive/v$pkgver.tar.gz"
"jellyfin-web-$pkgver.tar.gz::https://github.com/jellyfin/jellyfin-web/archive/v$pkgver.tar.gz"
'jellyfin.conf'
'jellyfin.service'
'jellyfin.sysusers'
'jellyfin.tmpfiles')
backup=('etc/conf.d/jellyfin')
sha512sums=('8484b322fb4a36b484570ec7660007d3ea70fcc4479cf8547f620375d559a4c2bca1134f1ca0ae2a1adaf7c9ae3575c57b26b0207b748a5f33b4fd374d77a057'
'd03c060da2ac5e4ea91a741affef6679df44500edaa1d7db2b9e95402228ac4e28b0eba03caf672cdbd8f2d1aeef40b5a61eb5b5c00ce27ed35f4e76758a912d'
'2aa97a1a7a8a447171b59be3e93183e09cbbc32c816843cc47c6777b9aec48bd9c1d9d354f166e0b000ad8d2e94e6e4b0559aa52e5c159abbc103ed2c5afa3f0'
'99d02080b1b92e731250f39ddd13ceca7129d69d0c05e0939620cbc3f499a9574668c63fa889704a4905560888131e980d7ab1fbcc5837b04d33ce26daa9d42b'
'6fc2638e6ec4b1ee0240e17815c91107b694e5fde72c1bc7956c83067bbeacb632de899b86837e47a0ec04288131b15c20746373b45e0669c8976069a55d627a'
'45a62b62d97b9a83289d4dfde684163b1bcf340c1921fb958e5a701812c61b392901841940c67e5fa5148783277d5b4dc65ba01d3a22e8f855ea62154ad9be33')
prepare() {
cd $pkgname-$pkgver
cp -r "$srcdir"/jellyfin-web-$pkgver/. MediaBrowser.WebDashboard/jellyfin-web
}
build(){
cd $pkgname-$pkgver
# Disable dotnet telemetry
export DOTNET_CLI_TELEMETRY_OPTOUT=1
dotnet build --configuration Release Jellyfin.Server
# Ideally, this would be run in package() with the --output variable pointing
# to "$pkgdir"/usr/lib/jellyfin, but this step fails in fakeroot.
# The makepkg output looks like
# Restore completed in 56.84 ms for /aur/jellyfin-git/src/jellyfin/Jellyfin.Server/Jellyfin.Server.csproj.
# ==> ERROR: A failure occurred in package().
# without indicating any sort of failure.
dotnet publish --configuration Release Jellyfin.Server --output "$PWD"/publish
# Clean up the runtimes folder (keep linux-*)
rm -rfv publish/runtimes/{alpine-*,osx*,tizen-*,win*}
}
package() {
mkdir -p "$pkgdir"/usr/lib
cp -dr --no-preserve='ownership' $pkgname-$pkgver/publish "$pkgdir"/usr/lib/jellyfin
install -Dm 644 jellyfin.service -t "$pkgdir"/usr/lib/systemd/system/
install -Dm 644 jellyfin.sysusers "$pkgdir"/usr/lib/sysusers.d/jellyfin.conf
install -Dm 644 jellyfin.tmpfiles "$pkgdir"/usr/lib/tmpfiles.d/jellyfin.conf
install -Dm 644 jellyfin.conf "$pkgdir"/etc/conf.d/jellyfin
}
# vim: ts=2 sw=2 et:
|