PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35

# Maintainer: Leon Möller <jkhsjdhjs at totally dot rip>

pkgname="jellyfin-web-intro-skipper"
pkgver=10.8.12
_commit=1c7c7937bb29fd71b5e4714c1445cb5bcd291609
pkgrel=1
pkgdesc="Modified jellyfin web client to use with the 'Intro Skipper' plugin"
arch=('any')
url="https://github.com/Bobby306/jellyfin-web"
license=('GPL2')
provides=("${pkgname%-intro-skipper}=$pkgver")
conflicts=("${pkgname%-intro-skipper}")
makedepends=('git' 'npm')
source=("$pkgname::git+$url.git#commit=$_commit")
sha256sums=('SKIP')

prepare() {
    cd "$pkgname"

    # jellyfin-web comes with a 'prepare' script, that runs the build when 'npm ci' is run
    # however, we want the build to run a separate step, so this script is skipped here
    # TODO: the script has been removed on the master branch, this can be removed with jellyfin-web 10.9
    # see also: https://bugs.archlinux.org/task/79713
    SKIP_PREPARE=1 npm ci --no-audit --no-fund --no-update-notifier
}

build() {
    cd "$pkgname"
    npm run build:production
}

package() {
    install -d "$pkgdir"/usr/share/jellyfin-web
    cp -r "$pkgname/dist/." "$pkgdir/usr/share/jellyfin-web/"
}