PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47

# Maintainer: Robin Marchart <robin.marchart at gmail dot com>
pkgname='jellyhaj-git'
pkgver=v0.2.0.r18.ga8539d7
pkgrel=2
pkgdesc="Terminal client for Jellyfin reimplementing parts of the web ui"
arch=('x86_64' 'aarch64')
url="https://github.com/owo-uwu-nyaa/jellyhaj"
license=('MIT')
depends=('mpv' 'sqlite' 'dbus' 'chafa')
makedepends=('cargo' 'clang' 'git')
provides=('jellyhaj')
conflicts=('jellyhaj')
options=(!lto)
source=('git+https://github.com/owo-uwu-nyaa/jellyhaj.git')
sha256sums=('SKIP')

prepare() {
  cd "jellyhaj" || exit
  export RUSTUP_TOOLCHAIN=stable
  cargo fetch --locked --target host-tuple
}

pkgver() {
  cd "jellyhaj" || exit
  git describe --long --tags --abbrev=7 | sed 's/\([^-]*-g\)/r\1/;s/-/./g'
}

build() {
  cd "jellyhaj" || exit
  export RUSTUP_TOOLCHAIN=stable
  export CARGO_TARGET_DIR=target
  cargo build --frozen --release -F mpris
}

check() {
  cd "jellyhaj" || exit
  export RUSTUP_TOOLCHAIN=stable
  export CARGO_TARGET_DIR=target
  cargo test --frozen --release -F mpris --workspace
}

package() {
  cd "jellyhaj" || exit
  install -Dm0755 -t "$pkgdir/usr/bin/" "target/release/jellyhaj"
  install -Dm0644 -t "$pkgdir/usr/share/applications/" "jellyhaj.desktop"
  install -Dm644 License.md -t "${pkgdir}/usr/share/licenses/${pkgname}/"
}