blob: 9cec7a13ff71fc86f331fa01419ef61352158799 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
|
# Maintainer: Chocobo1 <chocobo1 AT archlinux DOT net>
pkgname=jemalloc-git
pkgver=5.3.0.r60.g5f64ad60
pkgrel=1
pkgdesc="General purpose malloc implementation"
arch=('i686' 'x86_64')
url="https://jemalloc.net/"
license=('BSD')
depends=('glibc' 'sh')
makedepends=('git' 'docbook-xsl')
optdepends=('perl: for running jeprof')
provides=("jemalloc=$pkgver")
conflicts=('jemalloc')
source=("git+https://github.com/jemalloc/jemalloc.git")
sha256sums=('SKIP')
pkgver() {
cd "jemalloc"
git describe --long --tags | sed 's/\([^-]*-g\)/r\1/;s/-/./g'
}
build() {
cd "jemalloc"
_xslroot="/usr/share/xml/docbook/xsl-stylesheets-$(pacman -Q docbook-xsl | cut -d ' ' -f 2 | cut -d '-' -f 1)"
./autogen.sh \
--prefix="/usr" \
--with-xslroot="$_xslroot"
make
}
check() {
cd "jemalloc"
make check
}
package() {
cd "jemalloc"
make dist
make DESTDIR="$pkgdir" install
install -Dm644 "COPYING" -t "$pkgdir/usr/share/licenses/jemalloc"
find "$pkgdir" -name \*.a -type f -exec chmod 644 '{}' \;
}
|