blob: 28ce5fecbe7f86cd1751325c770eae897e2f81aa (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
|
# Maintainer: Chuan Ji <chuan@jichu4n.com>
pkgname=jfbview-git
pkgver=r414.4a8b0a7
pkgrel=1
pkgdesc="PDF and image viewer for the Linux framebuffer"
arch=('i686' 'x86_64' 'armv6h' 'armv7h' 'aarch64')
url="https://github.com/jichu4n/jfbview"
license=('Apache')
makedepends=('cmake')
depends=('ncurses' 'libjpeg-turbo' 'harfbuzz' 'freetype2' 'zlib' 'openjpeg2')
conflicts=('jfbpdf' 'jfbview')
replaces=('jfbpdf' 'jfbview')
source=("git+${url}.git")
sha512sums=('SKIP')
_pkgname='jfbview'
pkgver() {
cd "${_pkgname}"
printf "r%s.%s" "$(git rev-list --count HEAD)" "$(git rev-parse --short HEAD)"
}
prepare() {
cd "${srcdir}/${_pkgname}"
git submodule update --init --recursive
}
build(){
cd "${srcdir}/${_pkgname}"
cmake -H. -Bbuild \
-DBUILD_TESTING=OFF \
-DCMAKE_BUILD_TYPE=Release \
-DCMAKE_INSTALL_PREFIX=/usr
cmake --build build
}
package(){
cd "${srcdir}/${_pkgname}/build"
make DESTDIR="${pkgdir}" install
}
# vim:set ts=2 sw=2 et:
|