blob: 52b7a36a147597421723632e936f1ca50cb0769a (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
|
# Maintainer: Matt M <numbernine dot archlinux at complexnumber dot net>
pkgname=jfrog-cli-bin
_pkgname=jfrog-cli
pkgver=2.52.10
pkgrel=1
pkgdesc="Simple interface to Artifactory, Bintray and Mission Control"
arch=(x86_64 i686 armv7h aarch64)
url="https://github.com/jfrog/jfrog-cli"
license=(Apache)
conflicts=(jfrog-cli)
provides=(jfrog-cli)
_artifact_name="$pkgname-$pkgver-$pkgrel.jfrog"
_source_base="$_artifact_name::https://releases.jfrog.io/artifactory/$_pkgname/v2-jf/$pkgver"
source_x86_64=("$_source_base/$_pkgname-linux-amd64/jf")
source_i686=("$_source_base/$_pkgname-linux-386/jf")
source_armv7h=("$_source_base/$_pkgname-linux-arm/jf")
source_aarch64=("$_source_base/$_pkgname-linux-arm64/jf")
noextract=("$_artifact_name")
sha256sums_x86_64=('614db41e01d6b2b028e19905e7f37afd3aa3f8b614dfa93c22c2d91fc59d771e')
sha256sums_i686=('3f3cb241122ccc08d2d47c1a099445d11f26e929f5d7cc492e040ab62833524e')
sha256sums_armv7h=('b5c241cf27b64d48a71274af402424ae61477ae7d38701c50d358942987b6215')
sha256sums_aarch64=('585fe2efa30ade72468f6f2f5706f3fc01690590f82fc48f1a760569aab4116c')
_archive="$pkgname-$pkgver"
prepare() {
mkdir -p "$_archive"
mv "$_artifact_name" "$_archive/jfrog"
}
build() {
cd "$_archive"
chmod u+x jfrog
./jfrog completion bash > jfrog.bash
./jfrog completion fish > jfrog.fish
./jfrog completion zsh > jfrog.zsh
}
package() {
cd "$_archive"
install -Dm755 jfrog "$pkgdir/usr/bin/jfrog"
ln -rs "$pkgdir/usr/bin/jfrog" "$pkgdir/usr/bin/jf"
install -Dm644 jfrog.bash "$pkgdir/usr/share/bash-completion/completions/jfrog"
install -Dm644 jfrog.fish "$pkgdir/usr/share/fish/vendor_completions.d/jfrog.fish"
install -Dm644 jfrog.zsh "$pkgdir/usr/share/zsh/site-functions/_jfrog"
install -Dm644 jfrog.bash "$pkgdir/usr/share/bash-completion/completions/jf"
install -Dm644 jfrog.fish "$pkgdir/usr/share/fish/vendor_completions.d/jf.fish"
install -Dm644 jfrog.zsh "$pkgdir/usr/share/zsh/site-functions/_jf"
}
|