blob: cc8f85b0eaa6ccc5f9281d221df3ca602bd2203b (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
|
# Maintainer: David Runge <dvzrv@archlinux.org>
_name=jfrog
_upstream_name=jfrog-cli
pkgname=jfrog-cli-go
pkgver=1.39.7
pkgrel=1
pkgdesc="Simple interface to Artifactory, Bintray and Mission Control"
arch=('x86_64')
url="https://github.com/jfrog/jfrog-cli"
license=('Apache')
depends=('glibc')
makedepends=('git' 'go')
source=("$pkgname-$pkgver.tar.gz::https://github.com/jfrog/${_upstream_name}/archive/v${pkgver}.tar.gz")
sha512sums=('c4db5d3c5e293a46f009914581ec6ad9b46e2eb15cdf211cdff2912674a76d27210cface237b8316e6f60c0f4791e0cdaa1c6a9c103d087354932244ceded097')
b2sums=('f5b0430cc703410b6f1243367878804081972995df96e5dffc04a57c1767e89e8c66c6a82eae8391f895fa81519b604458f7c9455f429ddba6ecf888f2987c4b')
prepare() {
mv -v "${_upstream_name}-${pkgver}" "${pkgname}-${pkgver}"
}
build() {
cd "$pkgname-$pkgver"
export CGO_CPPFLAGS="${CPPFLAGS}"
export CGO_CFLAGS="${CFLAGS}"
export CGO_CXXFLAGS="${CXXFLAGS}"
export CGO_LDFLAGS="${LDFLAGS}"
export GOFLAGS="-buildmode=pie -trimpath -ldflags=-linkmode=external -mod=readonly -modcacherw"
go build
}
package() {
cd "$pkgname-$pkgver"
install -vDm 755 "${_upstream_name}" -t "${pkgdir}/usr/bin/"
install -vDm 644 {README,RELEASE}.md \
-t "${pkgdir}/usr/share/doc/${pkgname}"
}
|