blob: 5611d3f5179c9703c1812b4c94b6ab8dff8b2695 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
|
# Maintainer: David Runge <dvzrv@archlinux.org>
_name=jfrog
_upstream_name=jfrog-cli
pkgname=jfrog-cli-go
pkgver=1.45.1
pkgrel=1
pkgdesc="Simple interface to Artifactory, Bintray and Mission Control"
arch=('x86_64')
url="https://github.com/jfrog/jfrog-cli"
license=('Apache')
depends=('glibc')
makedepends=('git' 'go')
install=$pkgname.install
source=("$pkgname-$pkgver.tar.gz::https://github.com/jfrog/${_upstream_name}/archive/v${pkgver}.tar.gz")
sha512sums=('4db13d38976466e7a3922fb3ffbc9d07a39f4ffdb64c25f6bbb28739f56720d607b66793724665f6141d0b9de82a82d26c1daa9d7c1ac5c535bbcf40636825c6')
b2sums=('66ff5e3a392b338709a369605a233619e9566c54dd725d7618144a8c6c772f6845db20524593c4c821816f0cdd3b95c2af2cd0de8dabfcae62dbe5c269971b20')
build() {
cd "${_upstream_name}-${pkgver}"
export CGO_CPPFLAGS="${CPPFLAGS}"
export CGO_CFLAGS="${CFLAGS}"
export CGO_CXXFLAGS="${CXXFLAGS}"
export CGO_LDFLAGS="${LDFLAGS}"
export GOFLAGS="-buildmode=pie -trimpath -ldflags=-linkmode=external -mod=readonly -modcacherw"
go build -o ${_name}
}
package() {
cd "${_upstream_name}-${pkgver}"
install -vDm 755 ${_name} -t "${pkgdir}/usr/bin/"
install -vDm 644 {README,RELEASE}.md -t "${pkgdir}/usr/share/doc/${pkgname}"
}
|