blob: eb4e4e3de8c6705df7f0d68c174b04d532599eb7 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
|
# Maintainer: David Runge <dvzrv@archlinux.org>
_name=jfrog
_upstream_name=jfrog-cli
pkgname=jfrog-cli-go
pkgver=1.30.4
pkgrel=1
pkgdesc="Simple interface to Artifactory, Bintray and Mission Control"
arch=('x86_64')
url="https://github.com/jfrog/jfrog-cli-go"
license=('Apache')
depends=('glibc')
makedepends=('git' 'go-pie')
source=("$pkgname-$pkgver.tar.gz::https://github.com/jfrog/${_upstream_name}/archive/${pkgver}.tar.gz")
sha512sums=('3b7670ce138499630bfc9135e4d88e85fa1e65b871d5ee1b313dec388f229d00f228fcd350fa6156a5a0b64cbc8338753e4f94a237e54d6058f61b92e9629c30')
prepare() {
mv -v "${_upstream_name}-${pkgver}" "${pkgname}-${pkgver}"
(
cd "$pkgname-$pkgver/"
go mod vendor
# adding random resources: https://github.com/jfrog/jfrog-cli/issues/445
go run ./python/addresources.go
rm -v go.mod
)
export GOPATH="${srcdir}"
mkdir -vp src
mv -v "${pkgname}-${pkgver}"/vendor/* src/
mkdir -vp src/github.com/jfrog
ln -rTsf "${pkgname}-${pkgver}" src/github.com/jfrog/jfrog-cli-go
}
build() {
cd "$pkgname-$pkgver"
export GOPATH="${srcdir}"
go build -o "${_name}" \
-ldflags="-linkmode external -extldflags ${LDFLAGS} -s -w" \
"main.go"
}
package() {
cd "$pkgname-$pkgver"
# executable
install -vDm 755 "${_name}" -t "${pkgdir}/usr/bin/"
install -vDm 644 {CONTRIBUTING,README}.md \
-t "${pkgdir}/usr/share/doc/${pkgname}"
}
|