summarylogtreecommitdiffstats
path: root/PKGBUILD
blob: 6ba4e0ac99e586b1e5dcb2eb286b33a2cbbc1416 (plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
# Maintainer: Eric Engestrom <aur [at] engestrom [dot] ch>

pkgname=jing-git
pkgver=20181222
pkgrel=1
pkgdesc="RELAX NG validator"
url=https://github.com/relaxng/jing-trang
license=(BSD)
arch=(x86_64)
source=("git+$url"
        jing.sh)
sha256sums=('SKIP'
            'd7610d8e1446ac837f81bf0726fb7eaa3ed3d6d204bf02eb03f36aabf3ae0c00')
depends=(java-runtime)
makedepends=(java-environment)
provides=(jing=${pkgver%+*})
conflicts=(jing)

pkgver() {
  cd jing-trang
  git describe --abbrev=10 |
    sed 's/^V//; s/-/+/; s/-/./'
}

build() {
  cd jing-trang
  ./ant
}

check() {
  cd jing-trang
  ./ant test
}

package() {
  install -Dm755 jing.sh "$pkgdir"/usr/bin/jing
  install -dm755 "$pkgdir"/usr/share/java/jing/
  install -m644 jing-trang/build/jing.jar "$pkgdir"/usr/share/java/jing/
}