PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51

# Maintainer: Anatol Pomozov <anatol.pomozov@gmail.com>

pkgname=jiri-git
pkgver=r1166
pkgrel=1
pkgdesc='A tool for multi-repo development similar to Android repo'
arch=(i686 x86_64)
url='https://fuchsia.googlesource.com/jiri'
license=(MIT)
makedepends=(git go)
source=(git+https://fuchsia.googlesource.com/jiri)
sha1sums=('SKIP')

pkgver() {
  cd jiri
  echo r$(git rev-list --count master)
}

prepare() {
  cd jiri

  mkdir -p build
  mkdir -p .gopath/src/fuchsia.googlesource.com/
  ln -sf "$PWD" .gopath/src/fuchsia.googlesource.com/jiri
  export GOPATH="$PWD/.gopath"
}

build() {
  cd jiri

  go get -d github.com/libgit2/git2go
  mkdir -p "${GOPATH}/src/github.com/libgit2/git2go/vendor/libgit2/build"
  pushd "${GOPATH}/src/github.com/libgit2/git2go/vendor/libgit2/build"
  cmake -GNinja \
    -DCMAKE_BUILD_TYPE=RelWithDebInfo \
    -DCMAKE_C_FLAGS=-fPIC \
    -DTHREADSAFE=ON \
    -DBUILD_CLAR=OFF \
    -DBUILD_SHARED_LIBS=OFF \
    ..
  ninja
  popd

  go build -o build/jiri fuchsia.googlesource.com/jiri/cmd/jiri # -gccgoflags "$CFLAGS $LDFLAGS"
}

package() {
  cd jiri
  install -D -m755 build/jiri "$pkgdir"/usr/bin/jiri
  install -D -m644 scripts/jiri-bash-completion.sh "$pkgdir"/usr/share/bash-completion/completions/jiri
}