PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81

# Maintainer: Anatol Pomozov <anatol.pomozov@gmail.com>

pkgname=jiri-git
pkgver=r1331
pkgrel=1
pkgdesc='A tool for multi-repo development similar to Android repo'
arch=(i686 x86_64)
url='https://fuchsia.googlesource.com/jiri'
license=(MIT)
depends=(libgit2)
makedepends=(git go-pie cmake ninja python2)
source=(
  git+https://fuchsia.googlesource.com/jiri
  git+https://fuchsia.googlesource.com/third_party/git2go
  git+https://fuchsia.googlesource.com/third_party/boringssl#commit=438229a8d724058cb4de1af6814204f03ce734ed
  git+https://fuchsia.googlesource.com/third_party/curl#commit=280e8c6e371ebd0f2e0a907e016ab44d6c9549af
  git+https://fuchsia.googlesource.com/third_party/libssh2#commit=615210a03ecf36e1c55ffb7101d53e5c231c2f43
  git+https://fuchsia.googlesource.com/third_party/libgit2#commit=25a4b97b1bd0b5316deb77866756a3db772e08a2
  git+https://fuchsia.googlesource.com/third_party/zlib#commit=871bb1c83c0a4cc180c66ac89b14cb08675bef0d

  fix_libgit2_build.patch
)
sha1sums=('SKIP'
          'SKIP'
          'SKIP'
          'SKIP'
          'SKIP'
          'SKIP'
          'SKIP'
          '798fbefdda5144f30e9fe6bde7ef0df01c0e9caf')

pkgver() {
  cd jiri
  echo r$(git rev-list --count master)
}

prepare() {
  cd jiri

  sed -i 's/\bpython\b/python2/' scripts/build.sh
  # script sets GOPATH to fuchsia wide location, we do not have it
  sed -i 's/export GOPATH=.*//' scripts/build.sh
  mkdir -p go

  mkdir -p go/src/fuchsia.googlesource.com
  rm -rf go/src/fuchsia.googlesource.com/jiri
  ln -sfT $srcdir/jiri go/src/fuchsia.googlesource.com/jiri
  mkdir -p go/src/fuchsia.googlesource.com/jiri/vendor/github.com/libgit2
  rm -rf go/src/fuchsia.googlesource.com/jiri/vendor/github.com/libgit2/git2go
  ln -sfT $srcdir/git2go go/src/fuchsia.googlesource.com/jiri/vendor/github.com/libgit2/git2go
  mkdir -p go/src/fuchsia.googlesource.com/jiri/vendor/github.com/libgit2/git2go/vendor
  rm -rf go/src/fuchsia.googlesource.com/jiri/vendor/github.com/libgit2/git2go/vendor/boringssl
  ln -sfT $srcdir/boringssl go/src/fuchsia.googlesource.com/jiri/vendor/github.com/libgit2/git2go/vendor/boringssl
  mkdir -p go/src/fuchsia.googlesource.com/jiri/vendor/github.com/libgit2/git2go/vendor
  rm -rf go/src/fuchsia.googlesource.com/jiri/vendor/github.com/libgit2/git2go/vendor/curl
  ln -sfT $srcdir/curl go/src/fuchsia.googlesource.com/jiri/vendor/github.com/libgit2/git2go/vendor/curl
  mkdir -p go/src/fuchsia.googlesource.com/jiri/vendor/github.com/libgit2/git2go/vendor
  rm -rf go/src/fuchsia.googlesource.com/jiri/vendor/github.com/libgit2/git2go/vendor/libssh2
  ln -sfT $srcdir/libssh2 go/src/fuchsia.googlesource.com/jiri/vendor/github.com/libgit2/git2go/vendor/libssh2
  mkdir -p go/src/fuchsia.googlesource.com/jiri/vendor/github.com/libgit2/git2go/vendor
  rm -rf go/src/fuchsia.googlesource.com/jiri/vendor/github.com/libgit2/git2go/vendor/libgit2
  ln -sfT $srcdir/libgit2 go/src/fuchsia.googlesource.com/jiri/vendor/github.com/libgit2/git2go/vendor/libgit2
  mkdir -p go/src/fuchsia.googlesource.com/jiri/vendor/github.com/libgit2/git2go/vendor
  rm -rf go/src/fuchsia.googlesource.com/jiri/vendor/github.com/libgit2/git2go/vendor/zlib
  ln -sfT $srcdir/zlib go/src/fuchsia.googlesource.com/jiri/vendor/github.com/libgit2/git2go/vendor/zlib

  cd $srcdir/libgit2
  patch -p1 < ../fix_libgit2_build.patch
}

build() {
  cd jiri

  GOPATH=`pwd`/go ./scripts/build.sh
}

package() {
  cd jiri
  install -D -m755 build/jiri "$pkgdir"/usr/bin/jiri
  install -D -m644 scripts/jiri-bash-completion.sh "$pkgdir"/usr/share/bash-completion/completions/jiri
}