blob: 5059db41604ca795a638a604d4c41cb67f4f0c64 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
|
# Maintainer: Nick Cao <nickcao@nichi.co>
pkgbase=jool
pkgname=(jool-tools jool-dkms)
pkgver=4.1.7
pkgrel=1
pkgdesc="Open Source SIIT and NAT64 for Linux."
arch=('x86_64')
url="https://www.jool.mx"
license=('GPL2')
makedepends=('libnl')
optdepends=('iptables')
source=("https://github.com/NICMx/Jool/releases/download/v${pkgver}/jool-${pkgver}.tar.gz"
"jool.service"
"jool_siit.service"
)
sha256sums=('31fab9f9994e769b117354934742cfd8fc35a6a0aabcf4bab912bae4868c3778'
'2d50ad60e284876f09051a4d44d4cc51da4b354cb4ff7acf85de864427d360b5'
'0de3cc336ec9587bb3d62c81062977687a439403cc30d14d9798502d8626ce5f')
prepare() {
cp -a "${pkgbase}-${pkgver}" "${pkgbase}-${pkgver}-dkms"
}
build() {
cd "${pkgbase}-${pkgver}"
./configure --prefix=/usr
make
}
package_jool-tools() {
pkgdesc="Open Source SIIT and NAT64 for Linux. - Userspace tools and libraries"
depends=('libnl')
cd "${pkgbase}-${pkgver}"
make DESTDIR="${pkgdir}" install
install -D -m0644 "${srcdir}/jool.service" "${pkgdir}/usr/lib/systemd/system/jool.service"
install -D -m0644 "${srcdir}/jool_siit.service" "${pkgdir}/usr/lib/systemd/system/jool_siit.service"
}
package_jool-dkms() {
pkgdesc="Open Source SIIT and NAT64 for Linux. - Kernel modules"
depends=('dkms')
optdepends=('linux-headers: Build the module for Arch kernel'
'linux-lts-headers: Build the module for LTS Arch kernel')
install -dm 755 "${pkgdir}/usr/src"
cp -a --no-preserve='ownership' "${pkgbase}-${pkgver}-dkms" "${pkgdir}/usr/src/jool-${pkgver}"
}
|