blob: 472c01261cb3de72ba7d66399df72c8b67d3fbc6 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
|
# Maintainer: Yen Chi Hsuan <yan12125 at gmail dot com>
_pkgname=jpexs-decompiler
pkgname=$_pkgname-git
pkgver=10.0.0.r44.g79495fd0f
epoch=1
pkgrel=1
pkgdesc="Opensource flash SWF decompiler and editor"
arch=("any")
url="https://www.free-decompiler.com/flash/"
license=('GPL3')
makedepends=('git' 'apache-ant' 'java-environment=8' 'python')
depends=('java-runtime=8' 'bash') # bash for ffdec.sh
source=(
"git+https://github.com/jindrapetrik/jpexs-decompiler#branch=dev"
'put_version_into_build_xml.py'
)
md5sums=('SKIP'
'7f20d8a7ae9e6fc17e9ac45d31802499')
java_8_home() {
cd /usr/lib/jvm
java_8_folder=$(ls --directory java-8-* | head -n 1)
echo "/usr/lib/jvm/$java_8_folder"
}
pkgver() {
cd "${srcdir}/${_pkgname}"
( set -o pipefail
git describe --long --tag 2>/dev/null | sed 's/\([^-]*-g\)/r\1/;s/-/./g;s/^version//' ||
printf "r%s.%s" "$(git rev-list --count HEAD)" "$(git rev-parse --short HEAD)"
)
}
prepare() {
cd "${srcdir}/${_pkgname}"
python ../put_version_into_build_xml.py
}
build() {
cd "${srcdir}/${_pkgname}"
export JAVA_HOME="$(java_8_home)"
ant build
}
package() {
cd "${srcdir}/${_pkgname}"
install -Dm755 "resources/ffdec.sh" "${pkgdir}/usr/bin/ffdec"
install -Ddm755 "${pkgdir}/usr/share/java/${_pkgname}"
for f in dist/* ; do
cp -dr --no-preserve=ownership "$f" "${pkgdir}/usr/share/java/${_pkgname}"
done
install -Dm644 "license.txt" "${pkgdir}/usr/share/licenses/${_pkgname}/license.txt"
}
|