blob: 863cf112dc57153d89ea856dc0db14add9cdc361 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
|
# Maintainer: a821 at (nospam) mail de
# Contributor: Vincent Grande <shoober420@gmail.com>
# Contributor: Jan Alexander Steffens (heftig) <heftig@archlinux.org>
# Contributor: Geoffroy Carrier <geoffroy.carrier@koon.fr>
# Contributor: congyiwu <congyiwu AT gmail DOT com>
pkgname=json-c-git
pkgver=r1340.6e481aa
pkgrel=1
epoch=1
pkgdesc="A JSON implementation in C"
url="https://github.com/json-c/json-c/wiki"
license=(MIT)
arch=(x86_64)
depends=(glibc)
makedepends=(git cmake ninja)
provides=(libjson-c.so json-c)
conflicts=(json-c)
source=("git+https://github.com/json-c/json-c")
sha256sums=('SKIP')
pkgver() {
cd json-c
# no tags are reachable from HEAD
printf "r%s.%s" $(git rev-list --count HEAD) $(git rev-parse --short HEAD)
}
build() {
cmake -S json-c -B build -G Ninja \
-DCMAKE_BUILD_TYPE=None \
-DCMAKE_INSTALL_PREFIX=/usr \
-DCMAKE_INSTALL_LIBDIR=/usr/lib \
-DBUILD_STATIC_LIBS=OFF \
-DENABLE_THREADING=ON \
-DENABLE_RDRAND=OFF
cmake --build build
}
check() {
ctest --output-on-failure --stop-on-failure --test-dir build
}
package() {
DESTDIR="$pkgdir" cmake --install build
install -Dt "$pkgdir/usr/share/licenses/$pkgname" -m644 json-c/COPYING
}
# vim:set sw=2 et:
|