blob: 7441efa52c4900e70991a4aadcf0372fc9b365bc (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
|
# Maintainer: George Rawlinson <grawlinson@archlinux.org>
# Contributor: Thomas <thomas at 6f dot io>
pkgname=jujutsu
pkgver=0.6.1
pkgrel=1
pkgdesc='A git-compatible DVCS'
arch=('x86_64')
url='https://github.com/martinvonz/jj'
license=('Apache')
depends=('gcc-libs' 'zlib')
makedepends=('git' 'rust')
options=('!lto')
_commit='5caade2705d8f91afb0c26e67474470209d217be'
source=("$pkgname::git+$url#commit=$_commit")
b2sums=('SKIP')
pkgver() {
cd "$pkgname"
git describe --tags | sed 's/^v//'
}
prepare() {
cd "$pkgname"
# download dependencies
cargo fetch --locked --target "$CARCH-unknown-linux-gnu"
}
build() {
cd "$pkgname"
cargo build --frozen --release --all-features
for shell in bash fish zsh; do
./target/release/jj debug completion "--$shell" > "jj.$shell"
done
}
check() {
cd "$pkgname"
cargo test --frozen --all-features
}
package() {
cd "$pkgname"
# binary
install -vDm755 -t "$pkgdir/usr/bin" target/release/jj
# documentation
install -vDm644 -t "$pkgdir/usr/share/doc/$pkgname" README.md
cp -vr docs "$pkgdir/usr/share/doc/$pkgname"
# shell completions
install -vDm644 jj.bash "$pkgdir/usr/share/bash-completion/completions/jj"
install -vDm644 jj.fish "$pkgdir/usr/share/fish/vendor_completions.d/jj.fish"
install -vDm644 jj.zsh "$pkgdir/usr/share/zsh/site-functions/_jj"
}
|