blob: 4f07f730b07bdd3f40446020137959164e51be0d (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
|
# Maintainer: Gustavo Alvarez <sl1pkn07@gmail.com>
# Contributor: Dan Vratil <vratil@progdansoft.com>
pkgname=k3b-git
pkgver=17.04.00.r6067.58070f10f
pkgrel=1
pkgdesc="Feature-rich and easy to handle CD burning application. (Git version)"
arch=('i686' 'x86_64')
license=('GPL')
url='http://k3b.sourceforge.net'
depends=('qt5-webkit'
'knewstuff'
'kfilemetadata'
'knotifyconfig'
'kcmutils'
'libkcddb'
'musicbrainz'
'libdvdread'
'libmpcdec'
'libmad'
'hicolor-icon-theme'
)
makedepends=('git'
'cmake'
'extra-cmake-modules'
'kdoctools'
)
optdepends=('cdrdao: for CD DAO mode burning support'
'libburn: for CD, DVD & BluRay burning support'
'normalize: for WAV normalization'
'vcdimager: for VCD burning support'
'transcode: for advanced MPEG conversion support'
'sox: for encode audio files in formats such as AIFF or VOC'
'emovix: for bootable multimedia CD/DVD support'
)
provides=('k3b')
conflicts=('k3b')
source=('git://anongit.kde.org/k3b.git')
sha256sums=('SKIP')
pkgver() {
cd k3b
_ver="$(cat CMakeLists.txt | grep -m3 -e _VERSION_MAJOR -e _VERSION_MINOR -e _VERSION_MICRO | sed 's|K3B|KEB|' | grep -o "[[:digit:]]*" | paste -sd'.')"
echo "${_ver}.r$(git rev-list --count HEAD).$(git rev-parse --short HEAD)"
}
prepare() {
mkdir -p build
}
build() {
cd build
cmake ../k3b \
-DCMAKE_BUILD_TYPE=Release \
-DCMAKE_INSTALL_PREFIX=/usr \
-DKDE_INSTALL_LIBDIR=lib \
-DKDE_INSTALL_LIBEXECDIR=/usr/lib/k3b \
-DBUILD_TESTING=OFF \
-DK3B_ENABLE_PERMISSION_HELPER=ON
make
}
package() {
make -C build DESTDIR="${pkgdir}" install
}
|