blob: a7b4506197788cfb806bc2e5fcab31d10f3ea1b8 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
|
pkgname=kakoune-git
pkgver=2020.09.01_r635_g15aa4fe13
pkgrel=2
pkgdesc='Multiple-selection, UNIX-flavored modal editor'
arch=('x86_64' 'armv7h')
url='https://github.com/mawww/kakoune'
license=('custom:unlicense')
optdepends=(
'aspell: spell checking support'
'clang: add command for C/CPP insert mode completion support'
'ranger: provides file explorer functionality'
'tmux: tabbing support'
'universal-ctags-git: provides `readtags` used by `:tag` command to jump on a tag definition'
'xdotool: add support for kak windows switching (in grep, make... files)'
'xorg-xmessage: for nicer debugging messages'
)
makedepends=(
'git'
)
provides=("kakoune=${pkgver}")
conflicts=('kakoune')
source=("${pkgname}::git+https://github.com/mawww/kakoune.git")
sha256sums=('SKIP')
options=('!buildflags')
pkgver() {
cd "${srcdir}/${pkgname}"
git describe --tags | tr '-' '_' | sed 's/^v//; s/_/_r/'
}
check() {
cd "${srcdir}/${pkgname}/src"
make test
}
build() {
cd "${srcdir}/${pkgname}/src"
make
}
package() {
cd "${srcdir}/${pkgname}/src"
make install-strip DESTDIR="${pkgdir}" PREFIX=/usr
install -D ../UNLICENSE "${pkgdir}"/usr/share/licenses/${pkgname}/LICENSE
}
|